如何在Perl中猴子修补实例方法?

问题描述

我正在尝试猴子补丁(duck-punch :-)一个LWP::UserAgent实例，就像这样:

I'm trying to monkey-patch (duck-punch :-) a LWP::UserAgent instance, like so:

sub _user_agent_get_basic_credentials_patch {
  return ($username, $password);
}

my $agent = LWP::UserAgent->new();
$agent->get_basic_credentials = _user_agent_get_basic_credentials_patch;

这不是正确的语法-它产生:

This isn't the right syntax -- it yields:

我回想起

(从 Programming Perl 中)，调度查找是基于受祝福的包(我相信，是ref($agent))动态执行的，所以我不确定实例猴子修补甚至会如何在不影响祝福包裹的情况下工作.

As I recall (from Programming Perl), dispatch lookup is performed dynamically based on the blessed package (ref($agent), I believe), so I'm not sure how instance monkey patching would even work without affecting the blessed package.

我知道我可以继承UserAgent的子类，但是我希望使用更简洁的猴子修补方法.同意成年人，你有什么. ;-)

I know that I can subclass the UserAgent, but I would prefer the more concise monkey-patched approach. Consenting adults and what have you. ;-)

推荐答案

如果动态范围(使用local)不令人满意，则可以自动执行自定义软件包授权技术:

If dynamic scope (using local) isn't satisfactory, you can automate the custom package reblessing technique:

MONKEY_PATCH_INSTANCE:
{
  my $counter = 1; # could use a state var in perl 5.10

  sub monkey_patch_instance
  {
    my($instance, $method, $code) = @_;
    my $package = ref($instance) . '::MonkeyPatch' . $counter++;
    no strict 'refs';
    @{$package . '::ISA'} = (ref($instance));
    *{$package . '::' . $method} = $code;
    bless $_[0], $package; # sneaky re-bless of aliased argument
  }
}

示例用法:

package Dog;
sub new { bless {}, shift }
sub speak { print "woof!\n" }

...

package main;

my $dog1 = Dog->new;
my $dog2 = Dog->new;

monkey_patch_instance($dog2, speak => sub { print "yap!\n" });

$dog1->speak; # woof!
$dog2->speak; # yap!

这篇关于如何在Perl中猴子修补实例方法?的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持！