在VBA Excel中弹出图表

问题描述

我想知道是否有一种方法可以基于特定工作表中的值通过单击按钮在Excel中创建弹出式图表?
最好的方法是能够在VBA中做到这一点.

I was wondering if there is a way to create pop-up charts in Excel with press of a button, based on values found in a specific worksheet?
The best way would be to be able to do it in VBA.

我一直在研究，但找不到任何实际的解决方案.

I have been researching but can't find any real solutions.

有什么建议吗?

推荐答案

您！你这个幸运的家伙！ :p

You! You lucky guy! :p

自从我有空以来，我为您创建了一个基本版本. :)

Since I was free, I created a basic version for you. :)

要求:在用户表单中显示图表

Requirement: Show Chart in a Userform

逻辑:

1. 创建一个用户窗体，并在其中放置一个图像控件和一个命令按钮.
2. 确定图表的数据范围
3. 添加临时表
4. 在临时表中创建图表
5. 将图表作为bmp导出到用户的临时目录中
6. 使用该图像加载图像控件

假设:

我假设您图表的数据范围在[Sheet1]中，如下所示.请相应地修改代码.

I am assuming that your chart's data range is in [Sheet1] and look like this. Please amend the code accordingly.

准备用户表单

代码

此代码在用户表单代码区域中.我已经注释了该代码，以便您在理解它时不会有任何问题.如果还是这样，请发回.

This code goes in the userform code area. I have commented the code so that you will not have any problem understanding it. Still if you so, post back.

Private Declare Function GetTempPath Lib "kernel32" Alias "GetTempPathA" _
(ByVal nBufferLength As Long, ByVal lpBuffer As String) As Long

Private Const MAX_PATH As Long = 260

Private Sub CommandButton1_Click()
    Dim ws As Worksheet
    Dim wsTemp As Worksheet
    Dim rng As Range
    Dim oChrt As ChartObject

    '~~> Set the sheet where you have the charts data
    Set ws = [Sheet1]

    '~~> This is your charts range
    Set rng = ws.Range("A1:B3")

    '~~> Delete the temp sheeet if it is there
    Application.DisplayAlerts = False
    On Error Resume Next
    ThisWorkbook.Sheets("TempOutput").Delete
    On Error GoTo 0
    Application.DisplayAlerts = True

    '~~> Add a new temp sheet
    Set wsTemp = ThisWorkbook.Sheets.Add

    With wsTemp
        '~~> Give it a name so that we can delete it as shown above
        '~~> This is just a precaution in case `wsTemp.Delete` fails below
        .Name = "TempOutput"

        '~~~> Add the chart
        Set oChrt = .ChartObjects.Add _
            (Left:=50, Width:=300, Top:=75, Height:=225)

        '~~> Set the chart's source data and type
        '~~> Change as applicable
        With oChrt.Chart
            .SetSourceData Source:=rng
            .ChartType = xlXYScatterLines
        End With
    End With

    '~~> Export the chart as bmp to the temp drive
    oChrt.Chart.Export Filename:=TempPath & "TempChart.bmp", Filtername:="Bmp"

    '~~> Load the image to the image control
    Me.Image1.Picture = LoadPicture(TempPath & "TempChart.bmp")

    '~~> Delete the temp sheet
    Application.DisplayAlerts = False
    wsTemp.Delete
    Application.DisplayAlerts = True

    '~~> Kill the temp file
    On Error Resume Next
    Kill TempPath & "TempChart.bmp"
    On Error GoTo 0
End Sub

'~~> Function to get the user's temp path
Function TempPath() As String
    TempPath = String$(MAX_PATH, Chr$(0))
    GetTempPath MAX_PATH, TempPath
    TempPath = Replace(TempPath, Chr$(0), "")
End Function

输出:

当您运行用户窗体并按命令按钮时，您将在用户窗体中看到该图像.

When you run the userform and press the command button, you will see the image populate in the userform.

这篇关于在VBA Excel中弹出图表的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持！