Outlook 2011:向“等待回复"添加一些消息文件夹

问题描述

我的用例是我想跟踪我写的一些消息的回复.我现在的方法是等待发送消息，然后将其从已发送文件夹移动到我定期查看的等待回复"文件夹中.

My use case is that I want to track for responses on some messages I write. My methodology now is to wait for the message to be sent the move it from the sent folder to the "Waiting for reply" folder which I go over periodically.

我正在寻找一种方法来自动执行此操作.最好是我按下一个键，使 Outlook 既发送消息又将其放入等待文件夹中.例如，通过使用applescript.

I'm looking for a way to automate this. Best would be if I press a key which makes Outlook both send the message and put it in the Waiting folder. E.g., by using an applescript.

或者，我认为按下一个键会将我添加为密件抄送，并在消息底部添加一个WF"字符串.再次，使用applescript.然后，当我发送邮件时，它也会到达我的收件箱，如果邮件包含WF"

Alternatively, I thought that pressing a key will add me as BCC, and also add a "WF" string at the bottom of the message. Again, with applescript. Then when I send the message it will also arrive at my Inbox where I'll have a rule to move messages to "Waiting" if they contain "WF"

推荐答案

我从你的 其他线程 到这里:

tell application "Microsoft Outlook"
    -- Simple definition of target mail folder
    -- Works fine this way if only one folder with this name is available
    set waitingForReplyFolder to folder "Waiting for reply"

    -- bring Outlook to front
    activate

    -- remember the front window
    set theWindow to window 1

    -- check it's really draft
    if class of theWindow is not draft window then
        display dialog "Not a draft"
        return
    end if

    -- save the draft
    save theWindow

    -- get the id of the object of the draft window
    set myObjectID to id of (object of theWindow)

    -- close the message window
    close theWindow

    -- checking the message' subject
    set theSubject to subject of message id myObjectID

    -- send the message
    send message id myObjectID

    -- check and wait until Outlook has moved the mail to the sent folder
    -- move it to target folder after we have found it
    set mailFoundAndMoved to false
    repeat 20 times
        -- check the next 20 message ids
        repeat with idCounter from 1 to 20
            try
                set freshSentMail to outgoing message id (myObjectID + idCounter)
                -- check if the subject is the same (just to be safe)
                if subject of freshSentMail is equal to theSubject then
                    -- move the sent mail to the "waiting for reply" folder
                    move freshSentMail to waitingForReplyFolder
                    set mailFoundAndMoved to true
                    exit repeat
                end if
            on error errstr
            end try
        end repeat
        if mailFoundAndMoved then exit repeat
        delay 0.5
    end repeat

end tell

现在你必须看看如何触发它.打开一条新消息，编写内容等并运行此脚本.它会发送邮件并将其移动到您的目标文件夹，就在它出现在已发送文件夹中之后.

Now you must just see how to trigger this. Open a new message, write the content etc. and run this script. It will send the mail and move it to your target folder, just after it appeared inside the sent folder.

干杯，迈克尔/汉堡

这篇关于Outlook 2011:向“等待回复"添加一些消息文件夹的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持！