检查多个IP是否在线

问题描述

我目前有一个应用程序可以 ping 大约 50 件设备并显示向上"或向下"箭头，具体取决于它是否在线.它的问题是，它一次 ping 一个，这需要一段时间.我想看看有没有办法同时ping所有这些，并在它们出现时显示结果.

I currently have an application that pings around 50 pieces of equipment and displays a "Up" or "Down" arrow, depending if its online or not. The issue with it is, it pings one at a time, and that takes awhile. I want to see if there is a way to ping all of them at the same time, and display the results when they appear.

当前方法示例:

If My.Computer.Network.Ping(RouterBox.Text, 2000) Then
                'Online
                If GetPingMs(RouterBox.Text) < 125 Then
                    'Good ping
                    RouterPingIcon.Image = My.Resources.PingUP
                Else
                    'Bad ping
                    RouterPingIcon.Image = My.Resources.PingHIGH
                End If
            Else
                'Offline
                RouterPingIcon.Image = My.Resources.PingDOWN
            End If

注意:我在后台工作器中运行它.这个应用程序也是一个 WinForm.由于我当前的 ping 方法目前有大约 1000 行代码，我想找到一种不涉及整个重写的方法(如果可能的话).

Notes: I am running this within a Backgroundworker. This application is also a WinForm. Due to around 1000 lines of code currently for my current ping method, I would like to find a way that will not involve a entire rewrite (if possible).

推荐答案

这是我为简单实现您的 ping 技术而制作的帮助程序类.它利用 System.Net.NetworkInformation.Ping 类 及其SendAsync() 方法 执行异步 ping 请求.

Here's a helper class that I've made for a simple implementation of your ping technique. It utilizes the System.Net.NetworkInformation.Ping class and its SendAsync() method to perform an asynchronous ping request.

Imports System.Net.NetworkInformation

Public NotInheritable Class PingHelper
    Private Sub New() 'Create no instances of this class.
    End Sub

    'Events.
    Public Delegate Sub RequestsCompletedEventHandler(SentRequests As Tuple(Of String, PictureBox)()) 'The event handler signature.
    Public Shared Event RequestsCompleted As RequestsCompletedEventHandler 'The event for when all requests are done.

    'Instances of the state images.
    Private Shared Online As Image = My.Resources.Online
    Private Shared Offline As Image = My.Resources.Offline
    Private Shared HighPing As Image = My.Resources.HighPing

    'SyncLock object.
    Private Shared SyncLockObj As New Object

    'Keeping track of the requests.
    Private Shared AddressRequests As New List(Of Tuple(Of String, PictureBox)) 'The addresses of all current requests + their assigned picture boxes.
    Private Shared CompletedRequests As Integer = 0 'Self explanatory.

    ''' <summary>
    ''' Asynchronously sends a ping request to the specified endpoint and changes the image of the StatePictureBox based on the reply.
    ''' </summary>
    ''' <param name="Address">The IP-address or hostname to ping.</param>
    ''' <param name="Timeout">The maximum number of milliseconds to wait for a reply.</param>
    ''' <param name="StatePictureBox">The PictureBox which's image to change based on the reply.</param>
    ''' <remarks></remarks>
    Public Shared Sub PingAsync(ByVal Address As String, ByVal Timeout As Integer, ByVal StatePictureBox As PictureBox)
        Using PingRequest As New Ping
            AddHandler PingRequest.PingCompleted, AddressOf PingRequest_PingCompleted 'Adds an event handler to the PingCompleted event.
            PingRequest.SendAsync(Address, Timeout, StatePictureBox) 'Start the asynchronous ping request.
            AddressRequests.Add(New Tuple(Of String, PictureBox)(Address, StatePictureBox)) 'Add the address to the list.
        End Using
    End Sub

    'Event handler for when a ping request has completed.
    Private Shared Sub PingRequest_PingCompleted(sender As Object, e As System.Net.NetworkInformation.PingCompletedEventArgs)
        CompletedRequests += 1 'Increment the amount of completed requests.

        If CompletedRequests >= AddressRequests.Count Then 'Are all requests done?
            RaiseEvent RequestsCompleted(AddressRequests.ToArray()) 'All current requests are done, raise the RequestsCompleted event.

            'Reset the variables.
            AddressRequests.Clear()
            CompletedRequests = 0
        End If


        If e.UserState Is Nothing OrElse e.UserState.GetType() IsNot GetType(PictureBox) Then Return 'If UserToken is not a PictureBox do not continue execution.
        Dim StatePictureBox As PictureBox = DirectCast(e.UserState, PictureBox) 'Get the picture box which's image to change.

        SyncLock SyncLockObj 'SyncLock to fix concurrency issues.
            If e.Reply.Status = IPStatus.Success Then 'Ping succeeded.
                If e.Reply.RoundtripTime < 125 Then 'Is ping less than 125 ms?
                    StatePictureBox.Image = Online
                Else
                    StatePictureBox.Image = HighPing
                End If
            Else 'Ping failed, endpoint is not online or an error occurred.
                StatePictureBox.Image = Offline
            End If
        End SyncLock
    End Sub
End Class

注意:您必须将 Online/Offline/HighPing 图像变量更改为您自己的图像.

Note: You have to change the Online/Offline/HighPing image variables to your own images.

您可以使用 RequestsCompleted 事件来指示所有请求何时完成.

You can use the RequestsCompleted event to indicate when all requests have been completed.

示例用法:

Private Sub MainForm_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load
    AddHandler PingHelper.RequestsCompleted, AddressOf PingHelper_RequestsCompleted 'Subscribe to the "RequestsCompleted" event.
End Sub

Private Sub PingHelper_RequestsCompleted(SentRequests As Tuple(Of String, PictureBox)())
    Dim Message As String = String.Format("{0} requests completed:", SentRequests.Length) 'A message to display.
    For Each Request As Tuple(Of String, PictureBox) In SentRequests 'Iterate through all completed requests.
        Message &= Environment.NewLine & Request.Item1 'Add each IP-address/hostname on a new line in the message.
        'Request.Item1 = The address of the request.
        'Request.Item2 = The picture box which's image will be updated by the request.
    Next
    MessageBox.Show(Message, "Requests completed", MessageBoxButtons.OK, MessageBoxIcon.Information) 'Display the message.
End Sub

Private Sub PingButton_Click(sender As System.Object, e As System.EventArgs) Handles PingButton.Click
    'Send 10 ping requests to different endpoints.
    PingHelper.PingAsync(TextBox1.Text, 2000, PictureBox1)
    PingHelper.PingAsync(TextBox2.Text, 2000, PictureBox2)
    PingHelper.PingAsync(TextBox3.Text, 2000, PictureBox3)
    PingHelper.PingAsync(TextBox4.Text, 2000, PictureBox4)
    PingHelper.PingAsync(TextBox5.Text, 2000, PictureBox5)
    PingHelper.PingAsync(TextBox6.Text, 2000, PictureBox6)
    PingHelper.PingAsync(TextBox7.Text, 2000, PictureBox7)
    PingHelper.PingAsync(TextBox8.Text, 2000, PictureBox8)
    PingHelper.PingAsync(TextBox9.Text, 2000, PictureBox9)
    PingHelper.PingAsync(TextBox10.Text, 2000, PictureBox10)
End Sub

希望这会有所帮助！

这篇关于检查多个IP是否在线的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持！