将Applescript更改为单行NSApplescript源

问题描述

我正在构建一个应用程序，以学习在操作期间使用applescript发送多个命令的目的。下面是我要弄乱的代码，但是我删除了之间的动作，并用数字代替了它们。一切在applescript中都可以正常运行，但是将其放入NSApplescript initwithsource：行一直很麻烦。

Im building an app for learning purposes of using applescript to send multiple commands during an action. Below is the code I'm messing with but I have stripped out the actions in between the "" and replaced them with numbers. Everything works fine in applescript but making this into an NSApplescript initwithsource: line has been a bother.

tell application "Terminal"
    activate
    set currentTab to do script "1"
    do script "2" in currentTab
    do script "3" in currentTab
    do script "4" in currentTab
    delay 0.5
    tell application "Finder" to set visible of process "Terminal" to false
end tell

将此Applescript组合成一个单线？谢谢！

What is the best way to combine this applescript into a single line? Thanks!

推荐答案

使用AppleScript吗？ ：-D

Use AppleScript? :-D

首先，在AppleScript编辑器中，打开首选项窗口，然后单击选项以在菜单栏中显示脚本菜单。

First, in AppleScript Editor, open the Preferences window and click the option to Show Script menu in menu bar.

然后从屏幕右上方的脚本菜单项中选择打开脚本文件夹。

Then choose Open Scripts Folder from the script menu item up in the upper right of the screen.

使用以下脚本创建新的AppleScript .scptd文档：

Create a new AppleScript .scptd document with the following script:

tell application "AppleScript Editor"
    set string_ to text of first document

    -- make a list with each line of the script
    set stringLines to paragraphs of string_
    set originalDelims to AppleScript's text item delimiters

    -- add newlines 
    set AppleScript's text item delimiters to "\\n"

    -- now combine the items in the list using newlines
    set stringNewlines to stringLines as string

    set AppleScript's text item delimiters to "\""
    set stringNewlines to text items of stringNewlines
    set AppleScript's text item delimiters to "\\\""
    set stringNewlines to stringNewlines as string

    set AppleScript's text item delimiters to originalDelims
    set stringNewlines to "@\"" & stringNewlines & "\""

    set the clipboard to stringNewlines
end tell

（请注意，此脚本不是完美的：它对于像您提供的脚本之类的简单脚本也能正常工作，但无法自行转换。）

(Note that this script isn't perfect: it works fine for simple scripts like the one you provided, but isn't able to convert itself).

然后在AppleScript编辑器中打开要转换的脚本文档并使其成为前台文档，然后调用

Then open your script document you want to convert and make it the front document in AppleScript Editor. Then invoke the conversion script by choosing it from the Script menu.

鉴于您提供的脚本，它将产生以下常量 NSString ：

Given the script you provided, it should produce the following constant NSString:

@"tell application \"Terminal\"\n   activate\n  set currentTab to do script \"1\"\n do script \"2\" in currentTab\n do script \"3\" in currentTab\n do script \"4\" in currentTab\n delay 0.5\n tell application \"Finder\" to set visible of process \"Terminal\" to false\nend tell\n"

这篇关于将Applescript更改为单行NSApplescript源的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持！