持久变量存储在Automator中

问题描述

是否可以在自动化器工作流中存储持久值(特别是对于服务流)?

Is it possible to store a persistent value in an automator workflow (specifically for a service flow)?

似乎常规的自动化变量不是持久性的；例如尝试使用一个具有属性的applescript块(通常会持久保存)实际上也不会在Applescript中持久保存该属性(在测试中有效，但是在运行服务时该值也不会持久保存).

It seems that regular automator variables are not persistent; for instance trying to use an applescript chunk which has a property (which normally persists) does not actually persist the property in Applescript either (works in testing, but when you run the service the value doesn't persist).

有什么想法吗?

推荐答案

您可以使用脚本对象将数据存储在一个偏僻的地方.

You can use script objects to store your data in an out of the way place.

on run
    -- Path of script which holds data
    set thePath to (path to desktop as text) & "myData.scpt"
    --set thePath to (path to preferences as text) & "myData.scpt" -- better

    script theData
        property xxx : missing value
    end script

    try
        set theData to load script file thePath
    on error
        -- On first run, set the initial value of the variable
        set theData's xxx to 5
    end try

    -- change the value of the variable
    set theData's xxx to (theData's xxx) + 1

    -- save your changes
    store script theData in file thePath replacing yes
    return theData's xxx
end run

这篇关于持久变量存储在Automator中的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持！