如何使用PEG语言描述条件语句(If-Then-Else

问题描述

我正在开发Qt的qmake项目文件解析器(开源项目)。我在描述qmake的条件语句变体时遇到了麻烦，在文档中称为"作用域"。

EBNF(简化)：

ScopeStatement -> Condition ScopeBody

Condition -> Identifier | TestFunctionCall | NotExpr | OrExpr | AndExpr
NotExpr -> "!" Condition
OrExpr   -> Condition "|" Condition
AndExpr -> Condition ":" Condition

ScopeBody -> COLON Statement | BR_OPEN Statement:*  BR_CLOSE

Statement -> AssignmentStatement
AssignmentStatement -> Identifier EQ String

// There are many others built-in boolean functions
TestFunctionCall -> ("defined" | ...)  ARG_LIST_OPEN (String COMMA:?):* ARG_LIST_CLOSE

Identifier -> Letter (Letter | Digit | UNDERSCP):+ String -> (Letter | Digit | UNDERSCP):+

EQ -> "="
COLON -> ":"
COMMA -> ","
ARG_LIST_OPEN -> "("
ARG_LIST_CLOSE -> ")"
BLOCK_OPEN -> "{"
BLOCK_CLOSE -> "}"
UNDERSCP -> "_"

第一个问题：如何区分AND-操作符冒号和条件末尾冒号？有可能吗？

附注：我的语法草稿(没有函数调用支持)即使对于

这样的简单情况也不起作用

win32:xml: x = y

PEG.JS编码：

Start
  = ScopeStatement

// qmake scope statement
ScopeStatement
  = BooleanExpression ws* ((":" ws* SingleLineStatement) / ("{" ws* MultiLineStatement ))

SingleLineStatement
  = Identifier ws* "=" ws* Identifier lb* 

MultiLineStatement
  = (SingleLineStatement lb*)+

// qmake condition statement
BooleanExpression
  = BooleanOrExpression

BooleanOrExpression
  = left:BooleanAndExpression ws* "|" ws* right:BooleanOrExpression  { return {type: "OR", left:left, right:right} }
  / BooleanAndExpression

BooleanAndExpression
  = left:BooleanNotExpression ws* ":" ws* right:BooleanAndExpression  { return {type: "AND", left:left, right:right} }
  / BooleanNotExpression


BooleanNotExpression
  = "!" ws* operand:BooleanNotExpression { return {type: "NOT", operand: operand } }
  / BooleanComplexExpression


BooleanComplexExpression
  = Identifier
  / "(" logical_or:BooleanOrExpression ")" { return logical_or; }

Identifier
  = token:[a-zA-Z0-9_]+ { return token.join(""); }

ws 
  = [ 	]

lb
  = [
]

谢谢！

推荐答案

对于任何不是aBooleanAndExpression的内容，您需要在BooleanAndExpression后面包括一个负数前视，否则它将继续贪婪地使用其他"and"表达式。

Start
  = ScopeStatement

// qmake scope statement
ScopeStatement
  = bool:BooleanExpression ws* state:Statement  { return {bool:bool, state:state} }

Statement
  = ":" ws* state:SingleLineStatement  { return state }

SingleLineStatement
  = left:Identifier ws* "=" ws* right:Identifier lb*  { return {type: "ASSIGN", left:left, right:right} }

MultiLineStatement
  = (SingleLineStatement lb*)+

// qmake condition statement
BooleanExpression
  = BooleanOrExpression

BooleanOrExpression
  = left:BooleanAndExpression ws* "|" ws* right:BooleanOrExpression  { return {type: "OR", left:left, right:right} }
  / BooleanAndExpression

BooleanAndExpression
  = left:BooleanNotExpression ws* !(":" ws* SingleLineStatement) ":" ws* right:BooleanAndExpression  { return {type: "AND", left:left, right:right} }
  / BooleanNotExpression


BooleanNotExpression
  = "!" ws* operand:BooleanNotExpression { return {type: "NOT", operand: operand } }
  / BooleanComplexExpression


BooleanComplexExpression
  = Identifier
  / "(" logical_or:BooleanOrExpression ")" { return logical_or; }

Identifier
  = token:[a-zA-Z0-9_]+ { return token.join(""); }

ws 
  = [ 	]

lb
  = [
]

这篇关于如何使用PEG语言描述条件语句(If-Then-Else的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持！