F# 静态成员类型约束

问题描述

我正在尝试定义一个函数，factorize，它使用类似于 Seq.sum 的结构类型约束(需要静态成员 Zero、One、+ 和/)，以便它可以与 int、long、bigint 一起使用，等等.我似乎无法正确使用语法，也找不到有关该主题的大量资源.这就是我所拥有的，请帮忙.

I'm trying to define a function, factorize, which uses structural type constraints (requires static members Zero, One, +, and /) similar to Seq.sum so that it can be used with int, long, bigint, etc. I can't seem to get the syntax right, and can't find a lot of resources on the subject. This is what I have, please help.

let inline factorize (n:^NUM) =
    ^NUM : (static member get_Zero: unit->(^NUM))
    ^NUM : (static member get_One: unit->(^NUM))
    let rec factorize (n:^NUM) (j:^NUM) (flist: ^NUM list) =
        if n = ^NUM.One then flist
        elif n % j = ^NUM.Zero then factorize (n/j) (^NUM.One + ^NUM.One) (j::flist)
        else factorize n (j + ^NUM.One) (flist)
    factorize n (^NUM.One + ^NUM.One) []

推荐答案

我会这样写:

module NumericLiteralG = begin
  let inline FromZero() = LanguagePrimitives.GenericZero
  let inline FromOne() = LanguagePrimitives.GenericOne
end

let inline factorize n =
  let rec factorize n j flist =
    if n = 1G then flist
    elif n % j = 0G then factorize (n/j) j (j::flist)
    else factorize n (j + 1G) (flist)
  factorize n (1G + 1G) []

这里为 factorize 推断的类型太笼统了，但该函数将按您的预期工作.如果需要，您可以通过向某些通用表达式添加显式类型来强制使用更合理的签名和一组约束:

The type inferred for factorize here is way too general, but the function will work as you'd expect. You can force a more sane signature and set of constraints if you want by adding explicit types to some of the generic expressions:

let inline factorize (n:^a) : ^a list =
  let (one : ^a) = 1G
  let (zero : ^a) = 0G
  let rec factorize n (j:^a) flist =
    if n = one then flist
    elif n % j = zero then factorize (n/j) j (j::flist)
    else factorize n (j + one) (flist)
  factorize n (one + one) []

这篇关于F# 静态成员类型约束的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持！