这个ASP操作数据库的具体内容如下：
'获取数据库信息，N个结果字段，1个条件
Function GetDbDataN1(tbName,col,condition,conditionType,conditionValue)
GetDbDataN1 = ""
Dim arr()
Dim connT,cmdT,rsT,iCol
Set connT=Server.CreateObject("ADODB.Connection")
Set cmdT=Server.CreateObject("ADODB.Command")
connT.open dbstr
With cmdT
Set .ActiveConnection = connT
.CommandType = 1
.CommandText = "select top 1 " & col & " from " & tbName & " where " & condition & "=?"
If conditionType = "int" Then
.Parameters.Append .CreateParameter(condition,3,1,4,conditionValue)
Else
.Parameters.Append .CreateParameter(condition,200,1,64,conditionValue)
End If
set rsT=.Execute()
End With
Set cmdT.ActiveConnection = Nothing
set cmdT=nothing
if not rsT.eof then
colX = Split(col,",")
ReDim arr(UBound(colX))
For iCol=0 To UBound(colX)
arr(iCol)=rsT(colX(iCol))
Next
End If
rsT.close
connT.close
GetDbDataN1 = arr
End Function
解释一下GetDbDataN1这几个参数的含义：
tbName：数据库表名
col：要查询的字段名集合，格式为"字段1,字段2,字段3"，个数不限。如果只一个字段，就直接是"字段1"即可。
condition：条件名称，即主键的字段名
conditionType：条件的类型，即主键字段的类型，如果是整数就填int，如果是字符串，就填varchar
conditionValue：条件的值，即主键的值
函数的返回值
函数的返回值是一个数组，数组下标从0开始，下标最大值为要查询的字段数量减1.
使用举例：
如果有一个用户表（表名为tb_user），有user_id、user_name、user_right等多个字段。这时我想通过user_id来获取user_name和user_right，可以怎么通过这个asp数据库操作函数来实现呢？
user_id = 10 '已知user_id=10
Dim user_name,user_right
Dim userArr
userArr = GetDbDataN1("tb_user", "user_name,user_right", "user_id", "int", user_id)
user_name = userArr(0)
user_right = userArr(1)
关于根据主键参数化查询多个字段值的ASP数据库操作函数，本文就介绍这么多，希望对您有所帮助，谢谢！