class - Delphi 类 TList

我创建了一个简单的类，我将对象保存在 Generic list 中。我设法让它工作。但我不明白为什么这不起作用。

for Monster in MonsterList do
    begin
      Monster.Free;
      MonsterList.Remove(Monster);
    end;

如果我尝试从 MonsterList 中释放和删除这样的项目，它并没有真正删除，就我而言，名称消失了，但强度值保留在那里。如果我之后尝试列出 MonsterList 的内容，我总是只剩下一项。所以我用谷歌搜索了一下，在 Stack-overflow 上发现我的好解决方案是简单地倒数。

另一件事是当我将 Monsters 添加到 MonsterList 时，我添加了 3 个 Items ，但是如果我调试我看到 MonsterList 实际上有 0,1,2,3 3 是 NULL
这只有在我添加所有三个时才会发生，如果我只添加两个对象，它不会创建最终的 NULL 指针。这是在进行某种优化吗？

整个代码(不多)

unit MainForm;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, Generics.Collections, Generics.Defaults,
  System.Types;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    Memo2: TMemo;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

  TMonster = class
    private
      fName : string;
      fStrength : integer;
      fisDead : boolean;
    public
      constructor Create(Name : string; Strength : integer);
      destructor Destroy; override;

      property Name : string read fName write fName;
      property Strength : integer read fStrength write fStrength;
      property isDead : boolean read fisDead write fisDead;
  end;

var
  Form1: TForm1;
  MonsterList : TList<TMonster>;
  MonsterInstances : integer = 0;


implementation

{$R *.dfm}

constructor TMonster.Create(Name: string; Strength: integer);
begin

  inc(MonsterInstances);

  fName := Name;
  fStrength := Strength;
  fisDead := false;
end;

destructor TMonster.Destroy;
begin
  dec(MonsterInstances);

  inherited;
end;

procedure TForm1.Button1Click(Sender: TObject);
var Monster : TMonster;
    i : integer;
begin
  MonsterList := TList<TMonster>.Create;

  Memo2.Lines.Add(inttostr(MonsterInstances));

  MonsterList.Add(TMonster.Create('Jill',10));
  MonsterList.Add(TMonster.Create('Jane',1));
  MonsterList.Add(TMonster.Create('Rob',20));

  Memo2.Lines.Add(inttostr(MonsterInstances));

  for Monster in MonsterList do
    begin
      Memo1.Lines.Add(Monster.fName+ ' Strenght '+inttostr(Monster.fStrength)+' IsDead= '+booltostr(Monster.fisDead))
    end;

  MonsterList[1].isDead:=true;

  // not working
  {for Monster in MonsterList do
    begin
      Monster.Free;
      MonsterList.Remove(Monster);
    end; }

  // works
  for i := MonsterList.Count-1 downto 0 do
    begin
      if MonsterList[i].isDead = true then
        begin
          MonsterList[i].Free;
          MonsterList.Delete(i);
          MonsterList.Capacity:=MonsterList.Capacity-1;
        end;
    end;

  Memo1.Lines.Add('Survivors :');

  for Monster in MonsterList do
    Memo1.Lines.Add(Monster.Name+' Strenght '+inttostr(Monster.Strength));


  ShowMessage(inttostr(MonsterInstances));

end;

end.

谢谢!

最佳答案

您不能在像这样迭代列表时修改列表。相反，释放所有成员，然后清除列表。

for Monster in MonsterList do
  Monster.Free;
MonsterList.Clear;

这具有不调用 Remove 花费时间搜索项目的额外优势。

也许更简单的方法是使用 TObjectList<T> 并允许集合管理其成员的生命周期。然后你可以简单地调用 Clear 并且只要 OwnsObjects 是 True 所有成员都将被销毁并清除列表。

就您的第二个问题而言，如果添加三个项目，则有索引为 0、1 和 2 的项目。没有索引为 3 的项目。现在，在内部，集合很可能使用过度分配的内部数组。这样私有(private)内部数组的索引可以为 3。但是该内部数组的内容对您来说应该无关紧要。

关于class - Delphi 类 TList，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/50830198/