delphi - TPacker.SplitNode中的内存泄漏

我在网上找到了一个简单的二进制打包程序单元，我对其进行了更改以满足自己的需求。它工作正常，但我正在泄漏内存。

TSprite

type
  TSprite=class
  public
    X:Integer;
    Y:Integer;
    Width:Integer;
    Height:Integer;
    Used:Boolean;
    Down:TSprite;
    Right:TSprite;
    constructor Create(X, Y,Width, Height:Integer);
end;

TPacker

type
  TPacker=class
  public
  Root:TSprite;
  constructor Create(W,H:Integer; Image : TImage);
  destructor Destroy; override;
  function Fit(var Blocks:array of TBlock):Boolean;
  function FindNode(root:TSprite; W, H:Integer):TSprite;
  function SplitNode(Node:Tsprite; W, H:Integer):TSprite;
end;

我这样用

var Packer:TPacker;

  Packer:=TPacker.Create(Width  , Height, Image);

  Packer.Fit(Blocks);

  Boundary(Packer.Root, Image);

  for I := Low(Blocks) to High(Blocks) do
    begin
      if Blocks[I].Fit <> nil then
        Draw(Blocks[I].Fit.X,Blocks[I].Fit.Y,Blocks[I].Width,Blocks[I].Height, Image);
    end;



  LeftRacks:=Report(blocks, packer.Root.Width, packer.Root.Height).Racks;
  FillPercent:=Report(blocks, packer.Root.Width, packer.Root.Height).FillPercent;

  Packer.Free;

TPacker的构造方法

constructor TPacker.Create(W: Integer; H: Integer; Image : TImage);
var temp : integer;
begin
  // 100x100 is our smalles unit . So to create a nice Packview we always
  // change W,H to neerest value which is dividable by 100.
  temp:=0;
  temp:=W mod 100;
  W:=W-temp;

  temp:=0;
  temp:= H mod 100;
  H:=H-temp;

  Image.Width:=W+1;
  Image.Height:=H+1;

  Self.Root := TSprite.Create(0,0,W,H);
  Self.Root.Used:=false;
  Self.Root.Down:=nil;
  Self.Root.Right:=nil;
end;

这是我在析构函数中修复的第一个内存泄漏

destructor TPacker.Destroy;
begin
  FreeAndNil(Root);

  inherited;
end;

当前的泄漏发生在SplitNode中，因为它创建了新的节点，在这些节点中我失去了跟踪，而且我不知道如何正确释放它们。

function TPacker.SplitNode(Node: TSprite; W: Integer; H: Integer):TSprite;
begin
  Node.Used := true;
    Node.Down := TSprite.Create(Node.X , Node.Y + H , Node.Width , Node.Height - H);
    Node.Right := TSprite.Create(Node.X + W , Node.Y , Node.Width - W , H);
  Result := Node;
end;

在此SplitNode函数中使用Fit

function TPacker.Fit(var Blocks: array of TBlock):Boolean;
var
  I:Integer;
  Node:TSprite;
  temp:integer;
begin
   for I := Low(Blocks) to High(Blocks) do
    begin
      Node:=Self.FindNode(Self.Root, Blocks[I].Width, Blocks[I].Height);
      // we rotate it and try again just in case...
      if Assigned(Node) = false then
        begin
          temp:=Blocks[I].Width;
          Blocks[I].Width:=Blocks[I].Height;
          Blocks[I].Height:=temp;

          Node:=Self.FindNode(Self.Root, Blocks[I].Width, Blocks[I].Height);
        end;

      if Assigned(Node) then
        begin
          Blocks[I].Fit := Self.SplitNode(node, Blocks[I].Width, Blocks[I].Height);
        end;
    end;
end;

最佳答案

您可以在TSprite类中显式创建和销毁用作Root的TPacker。但是SplitNode在树结构中隐式创建了更多TSprite对象。没有自动机制可以清除这些其他对象。尽管引用了这些TSprite（Down和Right），所以每个TSprite都引用了被拆分成的其他TSprite并可以清理它们。如果每个人都进行清理，则将递归破坏整个树。

因此解决方案是为TSprite编写析构函数：

destructor TSprite.Destroy;
begin
  Down.Free;
  Right.Free;
  inherited;
end;

关于delphi - TPacker.SplitNode中的内存泄漏，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/54418800/