haskell - Bifunctor与Arrow方法

Bifunctor和Arrow方法之间有些重叠:

class Bifunctor p where
  first :: (a -> a') -> p a b -> p a' b
  second :: (b -> b') -> p a b -> p a b'
  bimap :: (a -> a') -> (b -> b') -> p a b -> p a' b'

class Arrow (~~>) where
  ...
  first :: (a ~~> a') -> (a, b) ~~> (a', b)
  second :: (b ~~> b') -> (a, b) ~~> (a, b')
  (***) :: (a ~~> a') -> (b ~~> b') -> (a, b) ~~> (a', b')

Bifunctor类具有与Functor完全相似的定律。
Arrow类带有许多不同法律的法律，以及有关(***)的一些暗含警告:“请注意，这通常不是仿函数。”令人惊讶的(对我而言)关于(***)只有一条法律:

first f >>> arr (id *** g) = arr (id *** g) >>> first f

Arrow (->)实例和Bifunctor (,)实例完全匹配，因此bimap @(,) = (***) @(->)。这有什么特殊意义吗？是否有有意义的假设

class Foo (~~>) p where
  biFoo :: (a ~~> a') -> (b ~~> b') -> p a b ~~> p a' b'

如果是这样，那是否承认功能依赖性？

最佳答案

Arrow是cartesian closed categories或至少cartesian monoidal categories类的(有点 SCSS )的前体。具体来说，对于张量积为(,)和单位元素()的单项类别。

回想一下monoidal category的特征在于张量积是bifunctor，因此Arrow和Bifunctor之间存在联系。

实际上，***的法律比您列出的要多，仅是库选择使用first来制定法律。这是该类的等效定义:

class (Category k, Category k') => EnhancedCategory k k' where
  arr :: k a b -> k' a b
  -- arr id ≡ id
  -- arr (f . g) = arr f . arr g
class (EnhancedCategory (->) a) => Arrow a where
  (***) :: a b c -> a b' c' -> a (b,b') (c,c')
  -- (f***id) . (g***id) ≡ (f.g)***id
  -- (id***f) . (id***g) ≡ id***(f.g)
  -- arr fst . (f***id) ≡ f . arr fst
  -- arr snd . (id***g) ≡ g . arr snd
  -- ¿ arr swap . (f***g) ≡ (g***f) . arr swap ?
  -- ((f***g)***h) . assoc ≡ assoc . (f***(g***h))
  diag :: a b (b,b)

first :: Arrow a => a b c -> a (b,d) (c,d)
first f = f***id
second :: Arrow a => a b c -> a (d,b) (d,c)
second g = id***g
(&&&) :: Arrow a => a b c -> a b d -> a b (c,d)
f&&&g = (f***g) . diag

顺便说一句，也可以删除arr来提升纯函数，而只给父类(super class)提供专用方法fst，snd和assoc。 I call that class Cartesian 。这允许定义不包含任意Haskell函数的“箭头”类别； linear maps是一个重要的示例。

关于haskell - Bifunctor与Arrow方法，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/57011605/