perl - 为什么我的 Perl 脚本中出现 "print() on closed filehandle with bad file descriptor"？

我在 Perl 中有一个 TCP 服务器(修订版 5.0 版本 8 颠覆 0)，它使用这个子程序来登录一个文件。

sub logger {
  return if ($LOGFILE eq "") ;
  my ($idt, $str) = @_ ;
  unless( defined($str) ) {
    $str = $idt ;
    $idt = '' ;
  }
  my ($s,$m,$h,$J,$M,$A) = localtime(time()) ;
  if(!open(OUT,">>$LOGFILE")) {
    warn "logger:error open [$LOGFILE]:[$!]\n";
    return;
  }
  if (!printf OUT "%4.4d/%2.2d/%2.2d %2.2d:%2.2d:%2.2d %s %s -> %s\n",
          $A+1900, $M+1, $J, $h, $m, $s, $idt, $HOSTNAME, $str) {
    warn "logger:error print [$LOGFILE]:[$!]\n";
    return;
  }
  if (!close(OUT)) {
    warn "logger:error close [$LOGFILE]:[$!]\n";
    return;
  }
}

所以这个日志文件是同时写入的。
特别是 ，我在 STDERR 中有这个错误:

printf() 在关闭的文件句柄上

记录器:错误打印 [/my/path/logFile.LOG]:[错误的文件描述符]

打开没有任何错误!

我该如何解决这个问题？

最佳答案

OUT 是一个全局包。假设升级到真正的日志系统(例如 Log4perl)是不可能的，您可以使用名为 $OUT 的词法文件句柄:

sub logger {
    $LOGFILE or return;
    my ($idt, $str) = @_ ;

    unless( defined($str) ) {
        $str = $idt ;
        $idt = '' ;
    }

    my ($s,$m,$h,$J,$M,$A) = localtime(time()) ;

    my $OUT;

    unless (open $OUT, '>>', $LOGFILE) {
        warn "logger:error open [$LOGFILE]:[$!]\n";
        return;
    }

    unless (printf $OUT
        "%4.4d/%2.2d/%2.2d %2.2d:%2.2d:%2.2d %s %s -> %s\n",
        $A+1900, $M+1, $J, $h, $m, $s, $idt, $HOSTNAME, $str
    ) {
        warn "logger:error print [$LOGFILE]:[$!]\n";
        return;
    }

    unless (close $OUT) {
        warn "logger:error close [$LOGFILE]:[$!]\n";
        return;
    }

    return 1;
}

关于perl - 为什么我的 Perl 脚本中出现 "print() on closed filehandle with bad file descriptor"？，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/10475045/