erlang - meck :validate? 有什么意义

作为 meck 的新手，我一直在整理一个显示各种功能的测试。但是，我无法理解为什么开发人员可能会调用 meck:validate。这是我的例子:

-module(meck_demo).

-include_lib("eunit/include/eunit.hrl").

validate_is_of_limited_use_test_() ->
    { foreach, fun setup_mock/0, fun cleanup_mock/1,
      [fun validate_does_not_fail_if_a_function_is_not_called/0,
       fun validate_does_not_fail_if_a_function_is_called_with_wrong_arity/0,
       fun validate_does_not_fail_if_an_undefined_function_is_called/0,
       fun validate_does_fail_if_a_function_was_called_with_wrong_argument_types/0,
       fun validate_does_fail_if_expectation_throws_an_unexpected_exception/0 ]}.

validate_does_not_fail_if_a_function_is_not_called() ->
    meck:expect(womble, name, fun() -> "Wellington" end),
    ?assert(meck:validate(womble)).

validate_does_not_fail_if_a_function_is_called_with_wrong_arity() ->
    meck:expect(womble, name, fun() -> "Madame Cholet" end),
    ?assertError(undef, womble:name(unexpected_arg)),
    ?assert(meck:validate(womble)).

validate_does_not_fail_if_an_undefined_function_is_called() ->
    ?assertError(undef, womble:fly()),
    ?assert(meck:validate(womble)).

validate_does_fail_if_a_function_was_called_with_wrong_argument_types() ->
    meck:expect(womble, jump, fun(Height) when Height < 1 ->
                                ok
                              end),
    ?assertError(function_clause, womble:jump(999)),
    ?assertNot(meck:validate(womble)).

validate_does_fail_if_expectation_throws_an_unexpected_exception() ->
    meck:expect(womble, jump, fun(Height) -> 42 = Height end),
    ?assertError({badmatch, 999}, womble:jump(999)),
    ?assertNot(meck:validate(womble)).

setup_mock() ->
    meck:new(womble, [non_strict]).

cleanup_mock(_SetupResult) ->
    meck:unload(womble).

我错过了什么？

-- 更新以反射(reflect)亚当解释的可以被捕获的情况

最佳答案

您设法解决了 validate 未涵盖的几乎所有案例(在 10c5063 中添加了更好的文档)。

验证可以检测:

当使用错误的参数类型 (function_clause) 调用函数时

抛出异常时

当抛出异常并预期(通过 meck:exception/2 )时，仍然导致 true 从 meck:validate/1

返回

验证无法检测:

当你没有调用函数时

当你调用一个带有错误数量的参数的函数时

如果你调用了一个未定义的函数

它无法检测到这些情况的原因是 Meck 的实现方式。 Meck 用模拟和维护模拟的过程替换模块。 Meck 得到的一切都通过那个模拟模块。 Meck 不会在调用者级别(即在您的模块或在您的测试用例中)插入自己，因此它无法知道您调用模块失败。上面测试用例中的所有失败都不会首先到达模拟模块。

关于erlang - meck :validate? 有什么意义，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/43279705/