delphi - 在 Delphi 5 中创建 Panel 的精确副本

我有一个 TPanel pnlMain，其中根据用户操作、数据验证等创建了几个动态 TPanel(并且 pnlMain 是它们的父级)。每个面板都包含一个充满字符串的彩色网格。除了面板，还有一些开源箭头组件和图片。一大堆东西。

现在我希望用户能够打印这个面板(我问怎么做 on this question )，但是在打印之前，用户必须看到一个包含 pnlMain 副本的新表单。在这个表单上，用户必须做一些更改，添加一些组件，然后打印他定制的 pnlMain 副本。打印后用户将关闭此表单并使用原始 pnlMain 返回原始表单。而且 - 正如您所猜到的 - 原始 pnlMain 必须保持不变。

那么有没有什么聪明的方法来复制整个 TPanel 及其内容呢？我知道我可以手动迭代 pnlMain.Controls 列表。

最佳答案

基于迭代子控件的代码，但无论如何都不错;-)

procedure TForm1.btn1Click(Sender: TObject);

    function CloneComponent(AAncestor: TComponent): TComponent;
      var
        XMemoryStream: TMemoryStream;
        XTempName: string;
      begin
        Result:=nil;
        if not Assigned(AAncestor) then
          exit;
        XMemoryStream:=TMemoryStream.Create;
        try
          XTempName:=AAncestor.Name;
          AAncestor.Name:='clone_' + XTempName;
          XMemoryStream.WriteComponent(AAncestor);
          AAncestor.Name:=XTempName;
          XMemoryStream.Position:=0;
          Result:=TComponentClass(AAncestor.ClassType).Create(AAncestor.Owner);
          if AAncestor is TControl then TControl(Result).Parent:=TControl(AAncestor).Parent;
          XMemoryStream.ReadComponent(Result);
        finally
          XMemoryStream.Free;
        end;
      end;

    var
      aPanel: TPanel;
      Ctrl, Ctrl_: TComponent;
      i: integer;
    begin
      //handle the Control (here Panel1) itself first
      TComponent(aPanel) := CloneComponent(pnl1);
      with aPanel do
      begin
        Left := 400;
        Top := 80;
      end;

      //now handle the childcontrols
      for i:= 0 to pnl1.ControlCount-1 do begin
        Ctrl := TComponent(pnl1.Controls[i]);
        Ctrl_ := CloneComponent(Ctrl);
        TControl(Ctrl_).Parent := aPanel;
        TControl(Ctrl_).Left := TControl(Ctrl).Left;
        TControl(Ctrl_).top := TControl(Ctrl).top;
      end;
    end;

来自 Delphi3000 文章的代码

关于delphi - 在 Delphi 5 中创建 Panel 的精确副本，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/1238122/