recursion - 在 Prolog 中查找每个 X 列表的程序

我开始学习 Prolog。该程序尝试获取给定元素的所有出现次数:

occurences(_, [], Res):- Res is [].
occurences(X, [X|T], Res):-
    occurences(X,T,TMP),
    Res is [X,TMP].
occurences(X, [_|T], Res):- occurences(X,T,Res).

但这里是错误:

?- occurences(a,[a,b,c,a],Res).
ERROR: is/2: Arithmetic: `[]/0' is not a function
^  Exception: (11) _G525 is [] ? creep
   Exception: (10) occurences(a, [], _G524) ? creep
   Exception: (9) occurences(a, [a], _G524) ? creep
   Exception: (8) occurences(a, [c, a], _G524) ? creep
   Exception: (7) occurences(a, [b, c, a], _G524) ? creep
   Exception: (6) occurences(a, [a, b, c, a], _G400) ? creep

最佳答案

除了其他人写的内容之外，请考虑使用 dif/2 约束:

occurrences(_, [], []).
occurrences(X, [X|Ls], [X|Rest]) :-
        occurrences(X, Ls, Rest).
occurrences(X, [L|Ls], Rest) :-
        dif(X, L),
        occurrences(X, Ls, Rest).

您现在可以在所有方向上使用谓词，例如:

?- occurrences(X, [a,a,b], Os).
X = a,
Os = [a, a] ;
X = b,
Os = [b] ;
Os = [],
dif(X, b),
dif(X, a),
dif(X, a) ;
false.

最后一个解决方案意味着如果 X 与 a 和 b 不同，则出现列表为空。

关于recursion - 在 Prolog 中查找每个 X 列表的程序，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/13662139/