delphi - 像 StrTok() 或 Sscanf() 之类的东西？

所以，我正在通过串行端口从 ModBos 读取数据，并获得类似于以下内容的读数:'+0020.8+0022.8-00.046-00.002-00.005-001.99+00.000+00.003';
基本上，总会有 8 个浮点读数，前面有一个加号或减号，尽管它们的字符长度可能不同。

获取浮点数组(或字符串数​​组或 TSringList)值的最有效方法是什么？

我不确定，但这可能是时间紧迫的，所以效率可能比优雅更重要。

最佳答案

我会做这样的事情:

type
  TFloatArray = array[0..7] of Double;

procedure ParseFloats(const aFloatStr: string;
  var aFloatArray: TFloatArray);
var
  lPos: Integer;
  lNextPos: Integer;
  lPosPositive: Integer;
  lPosNegative: Integer;
  i: Integer;
  lFormatSettings: TFormatSettings;
begin
  //do not forget formatsettings, or you will get problems with regional settings
  lFormatSettings.DecimalSeparator := '.';
  lFormatSettings.ThousandSeparator := ',';
  lPos := 1;
  for i := 0 to High(aFloatArray) do
  begin
    lPosPositive := PosEx('+', aFloatStr, lPos + 1);
    lPosNegative := PosEx('-', aFloatStr, lPos + 1);
    if lPosPositive = 0 then
      lNextPos := lPosNegative
    else if lPosNegative = 0 then
      lNextPos := lPosPositive
    else
      lNextPos := Min(lPosPositive, lPosNegative);
    if lNextPos = 0 then
      lNextPos := Length(aFloatStr) + 1;
    aFloatArray[i] := StrToFloat(Copy(aFloatStr, lPos, lNextPos - lPos), lFormatSettings);
    lPos := lNextPos;
  end;
end;

//call like this
var
  lFloats: TFloatArray;
begin
  ParseFloats('+0020.8+0022.8-00.046-00.002-00.005-001.99+00.000+00.003', lFloats);
end;

因为总是有 8 个浮点值，一个固定的 8 个 double 数组就足够了。我将字符串操作保持在最低限度，每个浮点值只复制一次字符串。重要的是 TFormatSettings，否则您将在小数点分隔符不是点的系统上出现错误(如我的)。

这里没有异常处理，我期望一个带有 8 个浮点值的字符串，仅此而已。

关于delphi - 像 StrTok() 或 Sscanf() 之类的东西？，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/4942374/