erlang - 正确使用erlang spawn_monitor

仍在研究Joe的书，并且很难全面了解监视器，尤其是spawn_monitor。这是我的代码；该练习要求编写一个函数，该函数将启动一个进程，该进程的工作是每5秒打印一次心跳，然后编写一个函数来监视上述进程并重新启动它。我没有进入重新启动的部分，因为我的监视器甚至无法检测到该过程发生了扭曲。

% simple "working" loop
loop_5_print() ->
    receive
    after 5000 ->
            io:format("I'm still alive~n"),
            loop_5_print()
    end.

% function to spawn and register a named worker
create_reg_keep_alive(Name) when not is_atom(Name) ->
    {error, badargs};
create_reg_keep_alive(Name) ->
    Pid = spawn(ex, loop_5_print, []),
    register(Name, Pid),
    {Pid, Name}.

% a simple monitor loop
monitor_loop(AName) ->
    Pid = whereis(AName),
    io:format("monitoring PID ~p~n", [Pid]),
    receive
        {'DOWN', _Ref, process, Pid, Why} ->
            io:format("~p died because ~p~n",[AName, Why]),
            % add the restart logic
            monitor_loop(AName)
    end.

% function to bootstrapma monitor
my_monitor(AName) ->
    case whereis(AName) of
        undefined -> {error, no_such_registration};

        _Pid -> spawn_monitor(ex, monitor_loop, [AName])
    end.

这是我在玩的游戏:

39> c("ex.erl").
{ok,ex}
40> ex:create_reg_keep_alive(myjob).
{<0.147.0>,myjob}
I'm still alive
I'm still alive
41> ex:my_monitor(myjob).
monitoring PID <0.147.0>
{<0.149.0>,#Ref<0.230612052.2032402433.56637>}
I'm still alive
I'm still alive
42> exit(whereis(myjob), stop).
true
43>

它肯定停止了loop_5_print“worker”-，但是监视器应该在哪一行打印？ 我看到的唯一解释是，以这种方式退出的进程发出的消息不是我在监视器循环的接收中匹配的模式。但这是本章书中介绍的唯一模式，因此我不购买此说明。

最佳答案

spawn_monitor不是您想要的。 spawn_monitor产生一个进程并立即开始监视它。当生成的进程死亡时，称为spawn_monitor的进程将收到一条消息，指出该进程已死。您需要从要接收DOWN消息的进程中调用erlang:monitor/2，第二个参数是要监视的Pid。

只需添加:

monitor(process, Pid),

后:

Pid = whereis(AName),

它的工作原理是:

1> c(ex).
{ok,ex}
2> ex:create_reg_keep_alive(myjob).
{<0.67.0>,myjob}
I'm still alive
I'm still alive
I'm still alive
3> ex:my_monitor(myjob).
monitoring PID <0.67.0>
{<0.69.0>,#Ref<0.2696002348.2586050567.188678>}
I'm still alive
I'm still alive
I'm still alive
4> exit(whereis(myjob), stop).
myjob died because stop
true
monitoring PID undefined