d - D编程语言中的等效 “yield return”是什么？

这是C#中的一个简单生成器。

    IEnumerable<int> Foo()
    {
        int a = 1, b = 1;
        while(true)
        {
            yield return b;
            int temp = a + b;
            a = b;
            b = temp;
        }
    }

如何在Digital Mars D中编写类似的生成器？

(问题是关于 yield 返回表的)

谢谢!

更新。
那很有意思。由于我只是在生成数学序列，因此使用recurrence可能是一个不错的选择。

auto fib = recurrence!("a[n-1] + a[n-2]")(1, 1);

foreach (e; take(fib, 10)) // <- prints first ten numbers from the sequence
{
    writeln(e);
}

最佳答案

D中没有确切的等效项。以下是一些粗略的等效项:

使用opApply样式的内部迭代。但是，这不允许在锁步中迭代两个迭代器:

struct Foo {
    int opApply(int delegate(ref int) dg) {
        int a = 1, b = 1;
        int result;
        while(true) {
            result = dg(b);
            if(result) break;
            int temp = a + b;
            a = b;
            b = temp;
        }

        return result;
    }
}

void main() {
    // Show usage:
    Foo foo;
    foreach(elem; foo) {
        // Do stuff.
    }
}

使用范围。在某些情况下，编写起来有些困难，但是却非常有效，并且可以进行锁步迭代。也可以使用foreach循环来进行迭代，就像opApply版本一样:

struct Foo {
    int a = 1, b = 1;

    int front() @property {
        return b;
    }

    void popFront() {
        int temp = a + b;
        a = b;
        b = temp;
    }

    // This range is infinite, i.e. never empty.
    enum bool empty = false;

    typeof(this) save() @property { return this; }
}

如果真的需要协程样式的东西，则可以使用core.thread.Fiber将范围和opApply结合在一起，但是您可能会发现range或opApply几乎总是满足您的需求。

关于d - D编程语言中的等效 “yield return”是什么？，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/3856653/