encoding - 将 `dir`输出重定向到文件后，编码不正确

我在欧洲的Windows cmd.exe上运行此代码，在这里使用本地设置作为我的语言。因此，我在目录名称中使用变音符号。

我尝试列出目录的名称，它们显示正确。然后将它们保存到文件中，但是当我在记事本中打开它时，变音符号不可读:例如，我使用Střední Čechy而不是Stýednˇ ¬echy。

我做错了什么，我该如何纠正？

@echo off
del directories.conf
FOR /F "delims=!" %%R IN ('dir * /b /a:d /o:n') DO (

 IF EXIST "%%R\scenery" (
  echo %%R
  echo %%R >> directories.conf
 ) ELSE (ECHO NOT INCLUDED %%R)

)
Echo Directory list created...
pause

最佳答案

尝试使用/u开关启动cmd.exe。这将导致cmd以UTF-16写入。

另外，您还需要使用chcp 1250切换到代码页1250(中欧的ANSI)。

您可以在批处理脚本中执行此操作。我为你做了一个。结构为:

.\Jižní Morava
.\Jižní Morava\scenery
.\Pelhřimov
.\Pelhřimov\scenery
.\Nic moc výlet
.\Střední Čechy
.\Střední Čechy\scenery

和脚本:

@echo off

if _%1_==_main_ (
    call :main
) else (
    cmd /u /c "%0 main"
)
goto :eof

:main
    chcp 1250
    del directories.conf
    for /F "delims=!" %%R in ('dir * /b /a:d /o:n') do (
        if exist %%R\scenery (
            echo %%R
            echo %%R >> directories.conf
        ) else (
            echo not included: %%R
        )
    )
    echo Directory list created...
    pause
goto :eof

另外，我建议您阅读andrewdotn's great answer的相关问题。

关于encoding - 将 `dir`输出重定向到文件后，编码不正确，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/9905740/