c# - .NET类加载器是否有工作的标准方法？

.NET类加载器是否有工作的标准方法？

说我编译这段代码：

Option Strict On : Option Explicit On

Module Module1
    Sub Main()
        System.Diagnostics.Debug.WriteLine("Main")
        Dim g = C.A
    End Sub
End Module

Public Class C
    Shared Sub New()
        System.Diagnostics.Debug.WriteLine("Init C")
    End Sub
    Shared Property A As New A
End Class

Public Class A
    Shared Sub New()
        System.Diagnostics.Debug.WriteLine("Init A")
    End Sub
    Public Sub New()
        System.Diagnostics.Debug.WriteLine("A Constructor")
    End Sub
End Class

我可以保证编译后的代码（在所有已实现的平台中）将具有以下输出吗？

Main
Init A
A Constructor
Init C

最佳答案

因为您使用的是构造函数而不是内联初始化，所以VB编译器不会用beforefieldinit标记类型，并且顺序是完全受控的。

但是，如果您编写了以下内容（使用内联初始化）：

Option Strict On : Option Explicit On

Module Module1
    Sub Main()
        System.Console.WriteLine("Main")
        Dim g = C.A
    End Sub
End Module
Public Class C
    Shared Function Narg() As A
        Dim alpha As New A
        System.Console.WriteLine("Init C")
        Return alpha
    End Function
    Shared Property A As A = Narg()
End Class
Public Class A
    Shared Sub New()
        System.Console.WriteLine("Init A")
    End Sub
    Public Sub New()
        System.Console.WriteLine("A Constructor")
    End Sub
End Class

订单是不确定的。允许使用与原始代码相同的顺序，但是C可以更早初始化。实际上，在我的系统上，输出为：

Init A
A Constructor
Init C
Main

原因是现在C标记为beforefieldinit。



随意挑剔：不，不保证您的原始代码具有该输出。在发行版上，它将没有输出，因为有条件地调用了System.Diagnostics.Debug。