javascript - PEGjs:在定义算术函数时请求帮助/指南

我正在学习PEGjs语法，因此需要以下方面的帮助或指南：

我有类似PRODUCT(), SUM(), DIVIDE()的功能

PRODUCT可以将数字/PRODUCT()/SUM()/DIVIDE(作为参数（除逗号以外的任何数字）

ex: PRODUCT(2, 5, SUM(5, 6, 7), DIVIDE(5, 2), PRODUCT(4, 6, 20, 12))

以同样的方式，SUM可以采用由逗号分隔的任意数量的参数。

Ex: SUM(4, 5, 10, DIVIDE(SUM(2, 5, 6), 3))

DIVIDE将采用两个参数（必须为2个），数字或另一个函数

Ex: DIVIDE(3, PRODUCT(3, 4, SUM(2, 3)))

有人可以帮助或指导我如何实现吗？

我到目前为止的规则

start = sum
  /multiply

multiply = "PRODUCT("a:digit "," __ b:digit ")" {return a * b}

sum = "SUM("a:digit "," b:digit ")"  {return a + b}

digit = [0-9]

__ = WhiteSpace*

WhiteSpace "whitespace"
  = [ \t\r\n]

上面的规则仅支持两个数字的乘积/和。如何实现以上目标？

提前致谢
曼朱纳斯·雷迪（Manjunath Reddy）

最佳答案

一个好的开始，但是您需要弄清楚如何解析参数列表并进行更多递归。

我发现最好的学习方法是通过示例（https://github.com/pegjs/pegjs/tree/master/examples）。

在online editor中尝试以下操作：

start
  = sum
  / multiply
  / divide

multiply
  = "PRODUCT(" _ args:arguments _ ")" { return args.reduce(function(a,b) {return a*b;}); }

sum
  = "SUM(" _ args:arguments _ ")"  { return args.reduce(function(a,b) {return a+b;}); }

divide
  = "DIVIDE(" _ dividend:argument _ "," _ divisor:argument _ ")" { return dividend / divisor; }

arguments
  = first:argument rest:(_ ',' _ arg:argument { return arg; })* { return [first].concat(rest); }

argument
  = multiply
  / sum
  / divide
  / number

number
  = digits:(digit)+ { return parseInt(digits.join(''), 10); }

digit = [0-9]

_ "optionalWhitespace"
  = whitespace *

whitespace
  = [ \t\n\r]+

例子：

PRODUCT(2, 5, SUM(5, 6, 7), DIVIDE(5, 2), PRODUCT(4, 6, 20, 12))
2592000
SUM(4, 5, 10, DIVIDE(SUM(2, 5, 6), 3))
23.333333333333332
DIVIDE(3, PRODUCT(3, 4, SUM(2, 3)))
0.05