wolfram-mathematica - 如何在Mathematica中求解递归关系的解析解

我有以下复发:

RSolve[{f[m, n] == f[m, n - 1] + f[m - 1, n],
        f[0, n] == 1, f[m, 0] == 1},
        f[m, n], {n}]

我尝试使用RSolve，但出现错误:

RSolve::deqx: Supplied equations are not difference equations
              of the given functions.

感谢你的帮助!

最佳答案

差分方程和初始条件为

Mathematica(7和8)不喜欢解决它……无论有没有初始条件。 RSolve表达式未评估

In[1]:= RSolve[{f[m,n]==f[m,n-1]+f[m-1,n],f[0,n]==f[m,0]==1},f[m,n],{m,n}]
        RSolve[{f[m,n]==f[m,n-1]+f[m-1,n]},f[m,n],{m,n}]
Out[1]= RSolve[{f[m,n]==f[-1+m,n]+f[m,-1+n],f[0,n]==f[m,0]==1},f[m,n],{m,n}]
Out[2]= RSolve[{f[m,n]==f[-1+m,n]+f[m,-1+n]},f[m,n],{m,n}]

我know that Mathematica使用generating functional methods(可能还有其他方法)来解决此类重复出现的问题，但我不知道为什么在这种简单情况下它失败了。

因此，让我们手动进行。

令g(x，n)为f(m，n)的生成函数

现在检查f(m + 1，n)x ^ m的总和

现在解决简单的代数差分方程:

也可以使用RSolve完成

In[3]:= RSolve[g[x,n]-x g[x,n]==g[x,n-1]&&g[x,0]==1/(1-x),g[x,n],n];
        Simplify[%,Element[n,Integers]]
Out[4]= {{g[x,n]->(1-x)^(-1-n)}}

现在提取x ^ m的系数:

In[5]:= SeriesCoefficient[(1 - x)^(-1 - n), {x, 0, m}]
Out[5]= Piecewise[{{(-1)^m*Binomial[-1 - n, m], m >= 0}}, 0]

将二项式简化为

In[6]:= FullSimplify[(-1)^m*Binomial[-n - 1, m] == Binomial[m + n, m], Element[{n,m}, Integers]&&m>0&&n>0 ]
Out[6]= True

所以我们终于得到了

可以使用符号和数字方式进行检查

In[7]:= ff[m_,n_]:=ff[m,n]=ff[m-1,n]+ff[m,n-1]
        ff[0,_]:=1;ff[_,0]:=1
In[9]:= And@@Flatten[Table[ff[m,n]==Binomial[n+m,m],{n,0,20},{m,0,20}]]
Out[9]= True

In[10]:= {f[m,n]==f[m,n-1]+f[m-1,n],f[0,n]==f[m,0]==1}/.f->(Binomial[#1+#2,#1]&)//FullSimplify
Out[10]= {True,True}