delphi - 我怎么称呼EnumWindowsProc？

我正在尝试列出计算机上所有正在运行的进程。

我的简短示例代码中的EnumWindowsProc()调用语句出了什么问题。我的编译器在这一行中声称:

EnumWindows(@EnumWindowsProc, ListBox1);

在函数调用中需要有一个变量。我应该如何将@EnumWindowsProc更改为var？

unit Unit_process_logger;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants,
  System.Classes, Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs,
  Vcl.ExtCtrls, Vcl.StdCtrls;

type
  TForm1 = class(TForm)
    ListBox1: TListBox;
    Timer1: TTimer;
    procedure Timer1Timer(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

function EnumWindowsProc(wHandle: HWND; lb: TListBox): Boolean;

var
  Form1: TForm1;

implementation

{$R *.dfm}

function EnumWindowsProc(wHandle: HWND; lb: TListBox): Boolean;
var
  Title, ClassName: array[0..255] of Char;
begin
  GetWindowText(wHandle, Title, 255);
  GetClassName(wHandle, ClassName, 255);
  if IsWindowVisible(wHandle) then
     lb.Items.Add(string(Title) + '-' + string(ClassName));
end;

procedure TForm1.Timer1Timer(Sender: TObject);
begin
  ListBox1.Items.Clear;
  EnumWindows(@EnumWindowsProc, ListBox1);
end;

end.

最佳答案

首先，声明是错误的。它必须是stdcall，并返回BOOL。

function EnumWindowsProc(wHandle: HWND; lb: TListBox): BOOL; stdcall;

其次，您的实现未设置返回值。返回True继续枚举，返回False停止枚举。在您的情况下，您需要返回True。

最后，您需要在调用LPARAM时将列表框强制转换为EnumWindows。

EnumWindows(@EnumWindowsProc , LPARAM(ListBox1));

有关完整的详细信息，请查询documentation。

放在一起，您将拥有:

function EnumWindowsProc(wHandle: HWND; lb: TListBox): BOOL; stdcall;
var
  Title, ClassName: array[0..255] of char;
begin
  GetWindowText(wHandle, Title, 255);
  GetClassName(wHandle, ClassName, 255);
  if IsWindowVisible(wHandle) then
    lb.Items.Add(string(Title) + '-' + string(ClassName));
  Result := True;
end;

procedure TForm1.Timer1Timer(Sender: TObject);
begin
  ListBox1.Items.Clear;
  EnumWindows(@EnumWindowsProc, LPARAM(ListBox1));
end;

另请注意，EnumWindows不会枚举所有正在运行的进程。它的作用是枚举所有顶级窗口。注意完全一样的事情。要枚举所有正在运行的进程，请使用EnumProcesses。但是，由于要读取窗口标题和窗口类名称，因此您可能确实想使用EnumWindows。

就像我之前说过的很多话，我讨厌EnumWindows的Delphi header 转换使用Pointer作为EnumWindowsProc参数的事实。这意味着您不能依赖编译器来检查类型安全性。我个人总是使用自己的EnumWindows版本。

type
  TFNWndEnumProc = function(hwnd: HWND; lParam: LPARAM): BOOL; stdcall;

function EnumWindows(lpEnumFunc: TFNWndEnumProc; lParam: LPARAM): BOOL;
  stdcall; external  user32;

然后，当您调用该函数时，您无需使用@运算符，因此让编译器检查您的回调函数是否正确声明:

EnumWindows(EnumWindowsProc, ...);