delphi - 如何在Delphi中响应对象属性字段中的更改

在Delphi 7中，从TGraphicControl继承新组件，并添加TFont属性，实现paint方法以使用TFont属性写入一些字符串。安装组件。

在设计时，使用属性对话框更改TFont属性时，该属性会立即反映在组件中。但是，当您更改TFont的各个属性（如Color或Size）时，除非将鼠标悬停在其上，否则组件不会重新绘制。

如何正确处理对象属性字段中的更改？

最佳答案

将事件处理程序分配给TFont.OnChange事件。在处理程序中，Invalidate()您的控件触发重新绘制。例如：

type
  TMyControl = class(TGraphicControl)
  private
    FMyFont: TFont;
    procedure MyFontChanged(Sender: TObject);
    procedure SetMyFont(Value: TFont);
  protected
    procedure Paint; override;
  public
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
  published
    property MyFont: TFont read FMyFont write SetMyFont;
  end;

constructor TMyControl.Create(AOwner: TComponent);
begin
  inherited;
  FMyFont := TFont.Create;
  FMyFont.OnChange := MyFontChanged;
end;

destructor TMyControl.Destroy;
begin
  FMyFont.Free;
  inherited;
end;

procedure TMyControl.MyFontChanged(Sender: TObject);
begin
  Invalidate;
end;

procedure TMyControl.SetMyFont(Value: TFont);
begin
  FMyFont.Assign(Value);
end;

procedure TMyControl.Paint;
begin
  // use MyFont as needed...
end;