xslt - 如何从XSLT的更深层次访问根属性

我正在调用模板：

<table>
    <xsl:apply-templates select="data/pics/row"/>
</table>

模板是

<xsl:template match="row">
    <tr>
        <xsl:for-each select="td">
            <td border="0">
                <a href="{@referencddePage}">
                    <img src="{pic/@src}" width="{pic/@width}" height="{pic/@height}"/>
                </a>
            </td>
        </xsl:for-each>
    </tr>
</xsl:template>

我的XML是：

<?xml version="1.0" encoding="iso-8859-8"?>
<?xml-stylesheet type="text/xsl" href="xslFiles\smallPageBuilder.xsl"?>
<data pageNo="3" referencePage="xxxxxxxxxxxxxxx.xml">
    <pics>
        <row no="0">
            <td col="0">
                <pic src="A.jpg" width="150" height="120"></pic>
            </td>
        </row>
    </pics>
</data>

我希望行:a h r e f="{@referencddePage}"从中获取输入
根:a h r e f= "{@referencddePage}"...，但我已经在<td level>中。

最佳答案

我想要这条线：a h r e
f =“ {@ referencddePage}”以获取
从根输入：a h r e f =
“ {@referencddePage}” ...但是我
已经在<td level>中


如果@referencePage属性始终是top元素的属性，那么可以始终按以下方式访问它：

/*/@referencePage

因此，在您的代码中，您将拥有：

<a href="{/*/@referencePage}">

我建议不要使用<xsl:for-each>并且仅使用and`。这样，生成的XSLT代码将更易于理解，并且将来可以更轻松地进行修改：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>
 <xsl:template match="row">
  <tr>
   <xsl:apply-templates/>
  </tr>
 </xsl:template>

 <xsl:template match="td">
   <td border="0">
     <a href="{/*/@referencePage}">
       <xsl:apply-templates/>
     </a>
   </td>
 </xsl:template>

 <xsl:template match="pic">
   <img src="{@src}" width="{@width}" height="{@height}"/>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于提供的XML文档时，

<data pageNo="3" referencePage="xxxxxxxxxxxxxxx.xml">
  <pics>
    <row no="0">
      <td col="0">
        <pic src="A.jpg" width="150" height="120"></pic>
      </td>
    </row>
  </pics>
</data>

产生所需的输出：

<tr>
   <td border="0">
      <a href="xxxxxxxxxxxxxxx.xml">
         <img src="A.jpg" width="150" height="120"/>
      </a>
   </td>
</tr>

看看每个模板是如此简单。而且，代码被进一步简化。

现在，代替：

   <img src="{pic/@src}" width="{pic/@width}" height="{pic/@height}"/>

我们只有：

   <img src="{@src}" width="{@width}" height="{@height}"/>