delphi - 在Delphi和C++ Builder中了解TBitmap.Scanline

Delphi＆C++ Builder的TBitmap类具有Scanline属性，该属性返回位图像素的内存。当我查看BMP文件的十六进制编辑器时，这似乎有所不同。

我正在尝试将C++ Builder应用程序移植到Java，并且想了解Scanline中的算法。如果我有文件，该如何像Scanline一样生成内存阵列？ Scanline的确切规范是什么？

澄清:BMP是Windows 24位DIB。我没有在代码中提供任何其他信息； C++ Builder似乎将其​​加载到某种类型的内存结构中，但不是逐字节的。想知道该结构的规范是什么。

最佳答案

位图文件以 BITMAPFILEHEADER 开头，bfOffBits成员指定图像数据的起始地址。这是Dh(第11-14个字节)处的DWORD。 Delphi VCL具有在“windows.pas”中定义为TBitmapFileHeader的结构。
ScanLine的最后一行指向该图像数据(自下而上)。 VCL在图像的bmBits( dsBm )成员的BITMAP成员或 DIBSECTION 中具有此值。当请求扫描线时，VCL会根据请求的行，行中的像素数(图像的宽度)以及构成像素的位数来计算偏移量，并返回指向该地址的指针，并将该偏移量添加到bmBits。它实际上是逐字节的图像数据。

下面的Delphi示例代码将24位位图读取到文件流，并将每个读取的像素与Bitmap.ScanLine对应的像素数据进行比较:

procedure TForm1.Button1Click(Sender: TObject);
var
  BmpFile: string;
  Bmp: TBitmap;

  fs: TFileStream;
  FileHeader: TBitmapFileHeader;
  InfoHeader: TBitmapInfoHeader;
  iHeight, iWidth, Padding: Longint;

  ScanLine: Pointer;
  RGBFile, RGBBitmap: TRGBTriple;
begin
  BmpFile := ExtractFilePath(Application.ExeName) + 'Attention_128_24.bmp';

  // laod bitmap to TBitmap
  Bmp := TBitmap.Create;
  Bmp.LoadFromFile(BmpFile);
  Assert(Bmp.PixelFormat = pf24bit);

  // read bitmap file with stream
  fs := TFileStream.Create(BmpFile, fmOpenRead or fmShareDenyWrite);
  // need to get the start of pixel array
  fs.Read(FileHeader, SizeOf(FileHeader));
  // need to get width and height of bitmap
  fs.Read(InfoHeader, SizeOf(InfoHeader));
  // just a general demo - no top-down image allowed
  Assert(InfoHeader.biHeight > 0);
  // size of each row is a multiple of the size of a DWORD
  Padding := SizeOf(DWORD) -
      (InfoHeader.biWidth * 3) mod SizeOf(DWORD); // pf24bit -> 3 bytes

  // start of pixel array
  fs.Seek(FileHeader.bfOffBits, soFromBeginning);


  // compare reading from file stream with the value from scanline
  for iHeight := InfoHeader.biHeight - 1 downto 0  do begin

    // get the scanline, bottom first
    ScanLine := Bmp.ScanLine[iHeight];

    for iWidth := 0 to InfoHeader.biWidth - 1 do begin

      // read RGB from file stream
      fs.Read(RGBFile, SizeOf(RGBFile));

      // read RGB from scan line
      RGBBitmap := TRGBTriple(Pointer(
                      Longint(ScanLine) + (iWidth * SizeOf(TRGBTriple)))^);

      // assert the two values are the same
      Assert((RGBBitmap.rgbtBlue = RGBFile.rgbtBlue) and
             (RGBBitmap.rgbtGreen = RGBFile.rgbtGreen) and
             (RGBBitmap.rgbtRed = RGBFile.rgbtRed));
    end;
    // skip row padding
    fs.Seek(Padding, soCurrent);
  end;
end;

有关在十六进制编辑器中查找位图文件的像素数据开始的图片: