windows - 批处理文件: pass parameter with white spaces to function

我正在使用批处理文件进行备份。我将选项传递给一个调用打包可执行文件的函数。除非参数包含空格，否则此方法有效。这是相关代码:

SET TARGET="%SAVEDIR%\XP.User.Documents.rar"
SET FILES="%DIRUSER%\Eigene Dateien\*"
SET EXLUCDE="%DIRUSER%\Documents\CDs"
call:funcBackup %TARGET% %FILES% %EXLUCDE%

:funcBackup
    SET TARGET=%~1
    SET FILES=%~2
    SET EXCLUDE=%~3
    echo."%PACKER% a -r -x"%EXCLUDE%" "%TARGET%" "%FILES%""
    ::call %PACKER% a -r -x"%EXCLUDE%" "%TARGET%" "%FILES%"
goto:eof

在XP(德语版)上，％DIRUSER％扩展为“Dokumente und Einstellungen”

在那种情况下，TARGET是正确的，但是FILES ==“Dokumente”和EXCLUDE ==“und”，
这意味着脚本由于％DIRUSER％中的空格而失败。

我怎样才能解决这个问题？

最佳答案

问题似乎出在您分配变量的风格上。
我想你像其他人一样设置DIRUSER变量

set DIRUSER="Dokumente und Einstellungen"

但是DIRUSER的内容则是"Dokumente und Einstellungen"，因此引号是内容的一部分。

但随后SET FILES="%DIRUSER%\Eigene Dateien\*"扩展为SET FILES=""Dokumente und Einstellungen"\Eigene Dateien\*"。

您可以使用set的扩展样式。set "var=content"这会将var的内容设置为content，不带任何引号，并且最后一个引号后面的所有附加空格都将被忽略。

所以你的代码是

set "SAVEDIR=D:\backup"
set "diruser=Dokumente und Einstellungen"
SET "TARGET=%SAVEDIR%\XP.User.Documents.rar"
SET "FILES=%DIRUSER%\Eigene Dateien\*"
SET "EXLUCDE=%DIRUSER%\Documents\CDs"
call:funcBackup "%TARGET%" "%FILES%" "%EXLUCDE%"
goto :eof

:funcBackup
    SET "TARGET=%~1"
    SET "FILES=%~2"
    SET "EXCLUDE=%~3"
    echo."%PACKER% a -r -x"%EXCLUDE%" "%TARGET%" "%FILES%"
    ::call %PACKER% a
goto :eof