perl - 如何在加载的模块中使用 Smart::Comments 而不更改其源？

如何指定为我的原始脚本以及它直接加载的任何模块加载 Smart::Comments。然而，由于它是一个源过滤器，如果应用于每个其他加载的模块加载的每个模块，它可能会造成严重破坏。

例如，我的脚本包括

use Neu::Image;

我也想为 Smart::Comments 加载 Neu::Image ，但指定

$ perl -MSmart::Comments script.pl

不为 Smart::Comments 加载 Neu::Image 。

此行为在 Smart::Comments documentation 中描述:



我已经看过的其他一些事情:

Perl Command-Line Options

perldoc perlrun(我搜索过
对于单词“模块”)

替代方法
正如 gbacon 所提到的，Smart::Comments 提供了一个允许打开或关闭它的环境变量选项。但是，如果可能的话，我希望能够在不修改原始源的情况下打开它。

最佳答案

几乎可以肯定，您想将use Smart::Comments添加到包含此类代码的模块中，然后通过适当设置$Smart_Comments来添加flip the switch in your environment。

偷渡，import-劫持猴子补丁是疯狂的。

但是也许您喜欢这种事情。假设您有Foo.pm:

package Foo;

use Exporter 'import';
our @EXPORT = qw/ foo /;

#use Smart::Comments;

sub foo {
  my @result;
  for (my $i = 0; $i < 5; $i++) {
    ### $i
    push @result => $i if $i % 2 == 0;
  }
  wantarray ? @result : \@result;
}

1;

普通用法:

$ perl -MFoo -e 'print foo, "\n"'
024

Ordinary is dull and boring, of course. With run-foo, we take bold, dashing steps!

#! /usr/bin/perl

use warnings;
use strict;

BEGIN {
  unshift @INC => \&inject_smart_comments;

  my %direct;
  open my $fh, "<", $0 or die "$0: open: $!";
  while (<$fh>) {
    ++$direct{$1} if /^\s*use\s+([A-Z][:\w]*)/;
  }
  close $fh;

  sub inject_smart_comments {
    my(undef,$path) = @_;
    s/[\/\\]/::/g, s/\.pm$// for my $mod = $path;
    if ($direct{$mod}) {
      open my $fh, "<", $path or die "$0: open $path: $!";
      return sub {
        return 0 unless defined($_ = <$fh>);
        s{^(\s*package\s+[A-Z][:\w]*\s*;\s*)$}
         {$1 use Smart::Comments;\n};
        return 1;
      };
    }
  }
}

use Foo;

print foo, "\n";

(请原谅紧凑性:我将其缩小，以便将其全部放入未滚动的块中。)

输出:

$ ./run-foo

### $ i:0

### $ i:1

### $ i:2

### $ i:3

### $ i:4
024

哇!

使用 @INC hooks，我们可以替换我们自己的或修改的源。该代码监视是否尝试对该程序直接使用的require模块进行尝试。命中时，inject_smart_comments返回一个迭代器，该迭代器一次产生一行。当这个狡猾，狡猾的迭代器看到程序包声明时，它会在该块后面附加一个看起来清白的use Smart::Comments，使它看起来好像一直在模块的源代码中一样。

例如，通过尝试使用正则表达式解析Perl代码，如果包声明本身不在一行上，则代码将中断。调味季节。

关于perl - 如何在加载的模块中使用 Smart::Comments 而不更改其源？，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/2156943/