delphi - Mac OS 64位上的Delphi FMX dcpcrypt错误结果

我正在使用Delphi 10.3.2
我正在尝试将DCPCrypt单元与firemonkey框架一起使用来加密字符串。
它可以在Win32，Win64和macOS 32目标上100％运行，结果始终相同。但是，当我针对macOS 64进行编译时，结果却有所不同。

这是使用的代码：

function EncodeAES(code:ansistring; key:ansistring):string;
var
    s,u:ansistring;
  enc: TEncoding;
  k,iv, Data, Crypt: TBytes;
  Cipher: TDCP_rijndael;
begin
    u:='';
    enc:=TEncoding.ANSI;
    Data := enc.GetBytes(code); // VMpuXJGbUNOv
    k:=enc.GetBytes(key);   // kj3214ed)k32nre2
    iv:=enc.GetBytes(u);
    Cipher:=TDCP_rijndael.Create(nil);
    Cipher.Init(K[0], 128, @iv[0]);
    Crypt:=Copy(Data, 0, Length(Data));
    BytePadding(Crypt, Cipher.BlockSize, pmPKCS7);
    Cipher.EncryptECB(Crypt[0], Crypt[0]);
    Cipher.Free;
    s:=tencoding.ANSI.GetString(crypt);
    result:=StringToHex(s);
end;

这是BytePadding函数：

procedure BytePadding(var Data: TBytes; BlockSize: integer; PaddingMode: TPaddingMode);
var
    I, DataBlocks, DataLength, PaddingStart, PaddingCount: integer;
begin
    BlockSize := BlockSize div 8;
    if PaddingMode in [pmZeroPadding, pmRandomPadding] then
        if Length(Data) mod BlockSize = 0 then Exit;
    DataBlocks := (Length(Data) div BlockSize) + 1;
    DataLength := DataBlocks * BlockSize;
    PaddingCount := DataLength - Length(Data);
    if PaddingMode in [pmANSIX923, pmISO10126, pmPKCS7] then
        if PaddingCount > $FF then Exit;
    PaddingStart := Length(Data);
    SetLength(Data, DataLength);
    case PaddingMode of
        pmZeroPadding, pmANSIX923, pmISO7816: // fill with $00 bytes
            FillChar(Data[PaddingStart], PaddingCount, 0);
        pmPKCS7: // fill with PaddingCount bytes
            FillChar(Data[PaddingStart], PaddingCount, PaddingCount);
        pmRandomPadding, pmISO10126: // fill with random bytes
            for I := PaddingStart to DataLength-1 do Data[I] := Random($FF);
    end;
    case PaddingMode of
        pmANSIX923, pmISO10126:
            Data[DataLength-1] := PaddingCount; // set end-marker with number of bytes added
        pmISO7816:
            Data[PaddingStart] := $80; // set fixed end-markder $80
    end;
end;

我将函数称为：

procedure TForm1.BtnClick(Sender: TObject);
var
    s:string;
begin
    s:=EncodeAES('VMpuXJGbUNOv','kj3214ed)k32nre2');
end;

Win32 / Win64 / macOS 32的结果（正确）：
E32A9DE47CC60BDB70CA27885128D17A

macOS 64的结果（错误）：
CF622155545E485AC3A083E8A0478493

我究竟做错了什么？

最佳答案

加密操作二进制数据，而不是文本数据。处理文本时，必须在加密之前将字符编码为字节，然后在解密后将字节解码为字符。这意味着在加密之前和解密之后使用相同的字符编码。您正在尝试进行这种编码，但是您没有考虑到TEncoding.ANSI在OS平台之间，甚至在使用同一OS平台的不同机器之间均不可移植的事实。为了更好的可移植性，您需要使用一致的编码，例如TEncoding.UTF8。

另外，TEncoding仅与UnicodeString一起使用，因此将TEncoding.GetBytes()和TEncoding.GetString()与AnsiString一起使用RTL定义的ANSI（而不是您自己）在ANSI和Unicode之间执行隐式转换，产生您可能不希望的字节如果您的字符串中包含任何非ASCII字符。

使用EncodeAES()进行所有字符串处理时，最好使用(Unicode)String函数，而忘记AnsiString甚至存在。尽管Linux之类的平台主要是UTF-8系统，但是Delphi的默认(Unicode)string在所有平台上都使用UTF-16。如果要编码ANSI字符串，请在调用代码希望使用RawByteString，UTF8String等时使用AnsiString(N)避免任何隐式转换。按原样加密8位字符，而根本不使用TEncoding。 TEncoding仅用于UnicodeString数据。

最后，您的EncodeAES()函数不应将加密的字节解码为UnicodeString只是将其转换为十六进制字符串。您应该按原样对加密的字节进行十六进制编码。

尝试以下方法：

function EncodeAES(const Data: TBytes; const Key: string): string; overload;
const
  Hex: array[0..15] of Char = ('0','1','2','3','4','5','6','7','8','9','A','B','C','D','E','F');
var
  enc: TEncoding;
  iv, k, Crypt: TBytes;
  Cipher: TDCP_rijndael;
  B: Byte;
  I: Integer;
begin
  enc := TEncoding.UTF8;
  iv := enc.GetBytes('');
  k := enc.GetBytes(Key);

  Cipher := TDCP_rijndael.Create(nil);
  try
    Cipher.Init(k[0], 128, @iv[0]);
    Crypt := Copy(Data, 0, Length(Data));
    BytePadding(Crypt, Cipher.BlockSize, pmPKCS7);
    Cipher.EncryptECB(Crypt[0], Crypt[0]);
  finally
    Cipher.Free;
  end;

  SetLength(Result, Length(Crypt)*2);
  I := Low(Result);
  for B in Crypt do
  begin
    Result[ I ] := Hex[(B shr 4) and $F];
    Result[I+1] := Hex[B and $F];
    Inc(I, 2);
  end;
end;

function EncodeAES(const S, Key: string): string; overload;
begin
  Result := EncodeAES(TEncoding.UTF8.GetBytes(S), Key);
end;

function EncodeAES(const S: RawByteString; const Key: string): string; overload;
begin
  Result := EncodeAES(BytesOf(S), Key);
end;