这试图解决3 * 3的线性方程并打印出结果，但是在注释行中出现了问题：
我在程序外部定义了LinearSolution模块，应该在内部定义它吗？有什么不同？
为什么说该语句是递归的，您知道，当我将这些语句用作普通子例程而不是模块子例程时，它们被验证为正确。
module LinearSolution
type LAE
integer::N
double precision,dimension(:,:),allocatable::A
double precision,dimension( :),allocatable::B
contains
procedure,nopass::RowReduction
end type LAE
contains
subroutine RowReduction
double precision::C
do k=1,N
do i=k+1,N
if(A(k,k)/=0) then
C=A(i,k)/A(k,k)
B(i)=B(i)-B(k)*C !error: Statement Function is recursive
do j=k+1,N
A(i,j)=A(i,j)-A(k,j)*C !error: Statement Function is recursive
end do
end if
end do
end do
do k=N,1,-1
do i=k-1,1,-1
if(A(k,k)/=0) then
C=A(i,k)/A(k,k)
B(i)=B(i)-B(k)*C !error: Statement Function is recursive
end if
end do
end do
do k=1,N
if(A(k,k)/=0) then
B(k)=B(k)/A(k,k) !error: Statement Function is recursive
end if
end do
end subroutine RowReduction
end module LinearSolution
program TestLAE
use LinearSolution !fatal error: cant open module file LinearSolution.mod for reading
type(LAE)::LAE1
LAE1%N=3
allocate(LAE1%B(1:N))
allocate(LAE1%A(1:N,1:N))
LAE1%B=(/1,1,1/)
LAE1%A=(/2,0,0,0,2,0,0,0,2/)
call LAE1%RowReduction
print*, LAE1%B(1),LAE1%B(2),LAE1%B(3)
end program
最佳答案
通常，implicit none是您的朋友。
让我们一次解决一个错误：
B(i)=B(i)-B(k)*C !error: Statement Function is recursive
在这种情况下，编译器无法识别
B；这里没有声明B的变量，因此最好的办法是假定它是将B定义为I的实数值statement function。语句函数虽然节省空间，但使函数定义方式混乱内联，但是除其他外，它们不能递归；在这里，您将根据B(i)定义B(i)，这显然会失败。（*）但是！你哭。
B是我的LAE类型的数组字段！是的，但是我们不在LAE的背景下；实际上，在此函数的上下文中，没有LAE类型的变量甚至不能使用B的值。这是因为该过程是在nopass中定义的；您需要有一个变量，该变量是要操作的对象，其类别为LAE，以便我们可以访问这些字段。看起来像这样： type LAE
!...
contains
procedure::RowReduction
end type LAE
contains
subroutine RowReduction(self)
class(LAE), intent(InOut) :: self
double precision::C
integer :: i, j, k
do k= 1, self%N
do i= k+1, self%N
if( self%A(k,k) /= 0 ) then
!....
注意，我们必须将self定义为
class(LAE)而不是type； class是类型的超集，在处理可扩展对象（包括具有（可重新分配）组件的对象）时是必需的。还要注意，我们还添加了隐式的none，它立即告诉您未定义B，因此指定了整数索引i，j和k。一旦正确地将
N，A和B引用为self的字段，则该程序的其余大部分都是正确的。请注意，您必须reshape您的LAE1%A数组：LAE1%A=reshape((/2,0,0,0,2,0,0,0,2/), (/N, N/))
但是否则情况似乎还不错。
module LinearSolution
implicit none
type LAE
integer::N
double precision,dimension(:,:),allocatable::A
double precision,dimension( :),allocatable::B
contains
procedure::RowReduction
end type LAE
contains
subroutine RowReduction(self)
class(LAE), intent(InOut) :: self
double precision::C
integer :: i, j, k
do k= 1, self%N
do i= k+1, self%N
if( self%A(k,k) /= 0 ) then
C = self%A(i,k) / self%A(k,k)
self%B(i) = self%B(i)- self%B(k)*C
do j=k+1, self%N
self%A(i,j) = self%A(i,j) - self%A(k,j)*C
end do
end if
end do
end do
do k = self%N,1,-1
do i=k-1,1,-1
if( self%A(k,k)/=0) then
C= self%A(i,k)/ self%A(k,k)
self%B(i)= self%B(i)- self%B(k)*C
end if
end do
end do
do k=1, self%N
if( self%A(k,k)/=0 ) then
self%B(k) = self%B(k) / self%A(k,k)
end if
end do
end subroutine RowReduction
end module LinearSolution
program TestLAE
use LinearSolution
implicit none
integer, parameter :: N = 3
type(LAE)::LAE1
LAE1%N=N
allocate(LAE1%B(1:N))
allocate(LAE1%A(1:N,1:N))
LAE1%B=(/1,1,1/)
LAE1%A=reshape((/2,0,0,0,2,0,0,0,2/), (/N, N/))
call LAE1%RowReduction
print*, LAE1%B(1),LAE1%B(2),LAE1%B(3)
end program
运行给出：
$ gfortran -o lae lae.f90 -Wall -std=f2003
$ ./lae
0.50000000000000000 0.50000000000000000 0.50000000000000000