wolfram-mathematica - 汇总理货柜台

很多时候，我发现自己使用Tally[ ]对出现的事件进行计数，然后，一旦我丢弃了原始列表，就不得不向该计数器添加(并加入)，从另一个列表中列出结果。

当我计算配置，出现次数，进行一些离散统计等时，通常会发生这种情况。

因此，我为Tally聚合定义了一个非常简单但方便的函数:

aggTally[listUnTallied__List:{},
         listUnTallied1_List,
         listTallied_List] :=
 Join[Tally@Join[listUnTallied, listUnTallied1], listTallied] //.
     {a___, {x_, p_}, b___, {x_, q_}, c___} -> {a, {x, p + q}, b, c};

这样的

l = {x, y, z}; lt = Tally@l;
n = {x};
m = {x, y, t};

aggTally[n, {}]
  {{x, 1}}

aggTally[m, n, {}]
  {{x, 2}, {y, 1}, {t, 1}}

aggTally[m, n, lt]
  {{x, 3}, {y, 2}, {t, 1}, {z, 1}}

此功能有两个问题:

1)表现

Timing[Fold[aggTally[Range@#2, #1] &, {}, Range[100]];]
  {23.656, Null}
(* functional equivalent to *)
Timing[s = {}; j = 1; While[j < 100, s = aggTally[Range@j, s]; j++]]
  {23.047, Null}

2)它不能验证最后一个参数是真实的Tallied列表还是null(尽管对我来说不太重要)

是否有一个简单，优雅，更快，更有效的解决方案？ (我知道这些要求太多，但是希望是免费的)

最佳答案

也许，这会适合您的需求？

aggTallyAlt[listUnTallied__List : {}, listUnTallied1_List, listTallied : {{_, _Integer} ...}] :=
{#[[1, 1]], Total@#[[All, 2]]} & /@
       GatherBy[Join[Tally@Join[listUnTallied, listUnTallied1], listTallied], First]

计时要好得多，并且对最后一个arg进行了基于模式的检查。

编辑:

这是一个更快的版本:

aggTallyAlt1[listUnTallied__List : {}, listUnTallied1_List, listTallied : {{_, _Integer} ...}] :=
Transpose[{#[[All, 1, 1]], Total[#[[All, All, 2]], {2}]}] &@
   GatherBy[Join[Tally@Join[listUnTallied, listUnTallied1], listTallied], First]

的时间安排:

In[39]:= Timing[Fold[aggTallyAlt1[Range@#2, #1] &, {}, Range[100]];]
Timing[s = {}; j = 1; While[j < 100, s = aggTallyAlt1[Range@j, s]; j++]]

Out[39]= {0.015, Null}

Out[40]= {0.016, Null}

关于wolfram-mathematica - 汇总理货柜台，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/5143575/