delphi - 德尔菲 “Free”的基础

在德尔福，我有一个基本的疑问。当我在设计时保留任何组件时，例如说TADOConnectuion并单击按钮，即使我编写以下代码，也不会出现任何错误:

begin
  ADOConnection.Free;  //No error
  ADOConnection.Free;  //No error
  ADOConnection.Free;  //No error
end;

但是，如果我在运行时创建了与follwos相同的对象，则会收到“访问冲突...”错误

begin
  ADOConnection := TADOConnection.create(self);
  ADOConnection.Free;  //No error
  ADOConnection.Free;  //Getting an "Access Violation..." error
end;

即使创建如下对象，也会遇到相同的错误:

ADOConnection := TADOConnection.create(nil);

只是想知道这种行为背后的原因，即为什么在设计时保留组件时没有错误？

最佳答案

如果释放组件，则会清除所有者中其对应的字段。如果添加设计时ADOConnection，则

ADOConnection.Free; // Frees ADOConnection and sets ADOConnection to nil
ADOConnection.Free; // Does nothing since ADOConnection is nil

您可以通过将其捕获到变量中来查看它:

var c: TADOConnection;
c := ADOConnection;
c.Free; // Frees ADOConnection and sets ADOConnection to nil
c.Free; // Error: c is not set to nil

即使在设计时创建了ADOConnection，这也行不通。

这是一个带有TButton组件的示例，该示例演示了您在设计时组件看到的行为是不是特定于设计时组件的:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
  published
    Button: TButton;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
begin
  Assert(not Assigned(Button));
  TButton.Create(Self).Name := 'Button'; // Button field gets set
  Assert(Assigned(Button));
  Button.Free;                           // Button field gets cleared
  Assert(not Assigned(Button));
  Button.Free;                           // Okay, Free may be called on nil values
end;

end.