groovy - 在类(class)应用类别

如果我想在一小段代码中使用Groovy类别，通常会这样

def foo() {

  use(TimeCategory) {
    new Date() + 5.hours
  }
}

但是，如果我想在同一类的多个方法中使用类别，则必须在每个方法中重复对use的调用很繁琐。

有没有办法在类级别应用类别？我尝试使用Groovy的@Mixin注释，如下所示:

import groovy.time.*

@Mixin(TimeCategory)
class Foo {

  Foo() {
    new Date() + 5.hours
  }
}

new Foo()

但是，如果您在Groovy控制台中执行上述代码，则会出现异常:

最佳答案

您可以在事实之后使用MetaClass.invokeMethod()。这有点丑陋，但可以使类代码保持相对干净:

import groovy.time.*

class Foo {
  Foo() {
    try { println (new Date() + 5.hours) }
    catch (e) { println e }

    try { println afterHours(5) }
    catch (e) { println e }
  }

  Date tomorrow() {
    new Date() + 1.days
  }

  Date nextWeek() {
    new Date() + 7.days
  }

  Date afterHours(int h) {
    new Date() + h.hours
  }
}

解决方案1:修改下游的Foo.metaClass如下:

Foo.metaClass.invokeMethod = { String name, args ->
  def metaMethod = Foo.metaClass.getMetaMethod(name, args)
  def result
  use(TimeCategory) {
    result = metaMethod.invoke(delegate.delegate, args)
  }
  return result
}

测试如下:

def foo = new Foo()
println "tomorrow: ${foo.tomorrow()}"
println "next week: ${foo.nextWeek()}"
println "after 7 hours: ${foo.afterHours(7)} "

产生以下结果

groovy.lang.MissingPropertyException: No such property: hours for class: java.lang.Integer
groovy.lang.MissingPropertyException: No such property: hours for class: java.lang.Integer
tomorrow: Fri Oct 17 14:46:52 CDT 2014
next week: Thu Oct 23 14:46:52 CDT 2014
after 7 hours: Thu Oct 16 21:46:52 CDT 2014

因此，它无法在构造函数中或通过构造函数工作，但在其他任何地方都可以工作。

如果您不介意全局更改Integer和Date的行为，则可以改用以下解决方案。

解决方案2:

使用与以前相同的类，而不是修改Foo.metaClass，而是按以下方式修改Integer.metaclass和Date.metaClass:

Integer.metaClass.mixin TimeCategory
Date.metaClass.mixin TimeCategory

现在，与之前相同的测试将产生以下输出:

Thu Oct 16 21:19:24 CDT 2014
Thu Oct 16 21:19:24 CDT 2014
tomorrow: Fri Oct 17 16:19:24 CDT 2014
next week: Thu Oct 23 16:19:24 CDT 2014
after 7 hours: Thu Oct 16 23:19:24 CDT 2014

关于groovy - 在类(class)应用类别，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/26240349/