delphi - 如何停止递归结点的TJvSearchFiles？

我正在使用这个JEDI组件枚举文件，但是我无法让它跳过结点。我可以对代码进行设置或修改以解决此问题吗？

我不确定jvsearchfiles.pas单元中的相关代码。但我认为它在这里：

function TJvSearchFiles.EnumFiles(const ADirectoryName: string;
  Dirs: TStrings; const Search: Boolean): Boolean;
var
  Handle: THandle;
  Finished: Boolean;
  DirOK: Boolean;
begin
  DoBeginScanDir(ADirectoryName);

  { Always scan the full directory - ie use * as mask - this seems faster
    then first using a mask, and then scanning the directory for subdirs }
  Handle := FindFirstFile(PChar(ADirectoryName + '*'), FFindData);
  Result := Handle <> INVALID_HANDLE_VALUE;
  if not Result then
  begin
    Result := GetLastError in [ERROR_FILE_NOT_FOUND, ERROR_ACCESS_DENIED];;
    Exit;
  end;

  Finished := False;
  try
    while not Finished do
    begin
      // (p3) no need to bring in the Forms unit for this:
      if not IsConsole then
        DoProgress;
      { After DoProgress, the user can have called Abort,
        so check it }
      if FAborting then
      begin
        Result := False;
        Exit;
      end;

      with FFindData do
        { Is it a directory? }
        if (dwFileAttributes and FILE_ATTRIBUTE_DIRECTORY > 0) then
        begin
          { Filter out '.' and '..'
            Other dir names can't begin with a '.' }

          {                         | Event | AddDir | SearchInDir
           -----------------------------------------------------------------
            doExcludeSubDirs        |
              True                  |   Y       N           N
              False                 |   N       N           N
            doIncludeSubDirs        |
              True                  |   Y       Y           Y
              False                 |   N       Y           Y
            doExcludeInvalidDirs    |
              True                  |   Y       Y           Y
              False                 |   N       Y           N
            doExcludeCompleteInvalidDirs |
              True                  |   Y       Y           Y
              False                 |   N       N           N
          }
          if not IsDotOrDotDot(cFileName) and
            ((soIncludeSystemHiddenDirs in Options) or not IsSystemAndHidden(FFindData)) then
            { Use case to prevent unnecessary calls to DoCheckDir }
            case DirOption of
              doExcludeSubDirs, doIncludeSubDirs:
                begin
                  if Search and (soSearchDirs in Options) and DoCheckDir then
                    DoFindDir(ADirectoryName);
                  if DirOption = doIncludeSubDirs then
                    Dirs.AddObject(cFileName, TObject(True))
                end;
              doExcludeInvalidDirs, doExcludeCompleteInvalidDirs:
                begin
                  DirOK := DoCheckDir;
                  if Search and (soSearchDirs in Options) and DirOK then
                    DoFindDir(ADirectoryName);

                  if (DirOption = doExcludeInvalidDirs) or DirOK then
                    Dirs.AddObject(cFileName, TObject(DirOK));
                end;
            end;
        end
        else
        if Search and (soSearchFiles in Options) and DoCheckFile then
          DoFindFile(ADirectoryName);

      if not FindNextFile(Handle, FFindData) then
      begin
        Finished := True;
        Result := GetLastError = ERROR_NO_MORE_FILES;
      end;
    end;
  finally
    Result := FindClose(Handle) and Result;
  end;
end;

这是上一个问题中给出的功能，但我无法使其正常工作。

function IsJunction(const FileName: string): Boolean;
const
  IO_REPARSE_TAG_MOUNT_POINT = $0A0000003;
var
  FindHandle: THandle;
  FindData: TWin32FindData;
begin
  Result := False;
  FindHandle := FindFirstFile(PChar(FileName), FindData);
  if FindHandle <> INVALID_HANDLE_VALUE then begin
    Result := ((FindData.dwFileAttributes and FILE_ATTRIBUTE_REPARSE_POINT)
                = FILE_ATTRIBUTE_REPARSE_POINT) and
                ((FindData.dwReserved0 and IO_REPARSE_TAG_MOUNT_POINT)
                = IO_REPARSE_TAG_MOUNT_POINT);
    winapi.windows.FindClose(FindHandle);
  end else
    RaiseLastOSError;
end;

最佳答案

您正在查看的函数已经跳过了目录：

if not IsDotOrDotDot(cFileName) and
   ((soIncludeSystemHiddenDirs in Options) or not IsSystemAndHidden(FFindData)) then

因此，您可以简单地扩展此条件。但是，我不会通过添加另一个and子句来扩展它。我个人认为这样的if语句非常不透明。我将介绍一个解释变量：

var
  SkipDirectory: Boolean;

然后像这样分配它：

if IsDotOrDotDot(cFileName) then
  SkipDirectory := True
else if IsSystemAndHidden(FFindData) and not (soIncludeSystemHiddenDirs in Options) then
  SkipDirectory := True
else if IsJunction(FFindData) then
  SkipDirectory := True
else
  SkipDirectory := False;

if not SkipDirectory then
  ....

然后，您需要重新整理IsJunction来接收TWin32FindData参数：

function IsJunction(const FindData: TWin32FindData): Boolean;
const
  IO_REPARSE_TAG_MOUNT_POINT = $0A0000003;
begin
  Result := ((FindData.dwFileAttributes and FILE_ATTRIBUTE_REPARSE_POINT)
              = FILE_ATTRIBUTE_REPARSE_POINT) and
              (FindData.dwReserved0 = IO_REPARSE_TAG_MOUNT_POINT);
end;

尽管我可能会重写@Sertac的if语句以将其分解。但这也许只是我个人的偏爱。

function FlagIsSet(Flags, Flag: DWORD): Boolean;
begin
  Result := (Flags and Flag)<>0;
end;

function IsJunction(const FindData: TWin32FindData): Boolean;
const
  IO_REPARSE_TAG_MOUNT_POINT = $0A0000003;
begin
  Result := FlagIsSet(FindData.dwFileAttributes, FILE_ATTRIBUTE_REPARSE_POINT)
            and (FindData.dwReserved0=IO_REPARSE_TAG_MOUNT_POINT);
end;