flowtype - 如何将FlowType与Spacemacs集成

我是spacemacs粉丝。我想使用Facebook Flow，但我不知道如何将其与spacemacs集成。我正在使用带有nuclide的流，但是我需要重新学习一切以提高工作效率。 flow存储库上有this script可以将其与emacs一起使用。我需要有关如何在spacemacs中使用它的指南。

谢谢。

最佳答案

我在这里使用Bodil的流程flycheckcheck配置:https://github.com/bodil/emacs.d/blob/d28264cf072bb8a62459a48813d0cb30804b4f5b/bodil/bodil-js.el#L121-L154

通过将以下内容添加到我的react-mode(https://github.com/saltycrane/.spacemacs.d/blob/9d985ace9251529c2b8d7857e2ec9835b103084c/init.el#L383-L414)中，使它可以与spacemacs的dotspacemacs/user-config和默认的eslint flychecker一起使用:

;; Flow (JS) flycheck config (http://flowtype.org)
;; from https://github.com/bodil/emacs.d/blob/master/bodil/bodil-js.el
(require 'f)
(require 'json)
(require 'flycheck)

(defun flycheck-parse-flow (output checker buffer)
  (let ((json-array-type 'list))
    (let ((o (json-read-from-string output)))
      (mapcar #'(lambda (errp)
                  (let ((err (cadr (assoc 'message errp))))
                    (flycheck-error-new
                     :line (cdr (assoc 'line err))
                     :column (cdr (assoc 'start err))
                     :level 'error
                     :message (cdr (assoc 'descr err))
                     :filename (f-relative
                                (cdr (assoc 'path err))
                                (f-dirname (file-truename
                                            (buffer-file-name))))
                     :buffer buffer
                     :checker checker)))
              (cdr (assoc 'errors o))))))

(flycheck-define-checker javascript-flow
  "Javascript type checking using Flow."
  :command ("flow" "--json" source-original)
  :error-parser flycheck-parse-flow
  :modes react-mode
  :next-checkers ((error . javascript-eslint))
  )
(add-to-list 'flycheck-checkers 'javascript-flow)

另外，请确保已安装Flow命令行工具。像这样安装它:

npm install -g flow-bin

我认为Bodil打算使消息简短，但是我想让flycheck显示更多详细消息。如果有人知道该怎么做，我将不胜感激。

EDIT 2016-08-12:我发布的原始版本在初始加载时给出了Symbol's function definition is void: flycheck-define-checker错误。我更新了上面的代码，添加了require 'flycheck来消除该错误。