opengl - 为什么我的镜面反射高光在多边形边缘上显示得如此强烈？

我有一个简单的应用程序，该应用程序用一个定向光绘制一个球体。我通过以八面体开始并将每个三角形细分为4个较小的三角形来创建球体。

仅使用漫射照明，球体看起来非常光滑。但是，当我添加镜面高光时，三角形的边缘显示得相当强烈。这里有些例子:

仅扩散:

漫反射和镜面反射:

我相信法线可以正确插值。只看法线，我得到这个:

实际上，如果我切换到平面阴影，其中法线是每个多边形而不是每个顶点，则可以得到以下信息:

在我的顶点着色器中，我将模型的法线与转置逆模型视图矩阵相乘:

#version 330 core

layout (location = 0) in vec4 vPosition;
layout (location = 1) in vec3 vNormal;
layout (location = 2) in vec2 vTexCoord;

out vec3 fNormal;
out vec2 fTexCoord;

uniform mat4 transInvModelView;
uniform mat4 ModelViewMatrix;
uniform mat4 ProjectionMatrix;

void main()
{
    fNormal = vec3(transInvModelView * vec4(vNormal, 0.0));
    fTexCoord = vTexCoord;
    gl_Position = ProjectionMatrix * ModelViewMatrix * vPosition;
}

在片段着色器中，我按如下方式计算镜面反射高光:

#version 330 core

in vec3 fNormal;
in vec2 fTexCoord;

out vec4 color;

uniform sampler2D tex;
uniform vec4 lightColor;        // RGB, assumes multiplied by light intensity
uniform vec3 lightDirection;    // normalized, assumes directional light, lambertian lighting
uniform float specularIntensity;
uniform float specularShininess;
uniform vec3 halfVector;        // Halfway between eye and light
uniform vec4 objectColor;

void main()
{
    vec4    texColor    = objectColor;

    float   specular    = max(dot(halfVector, fNormal), 0.0);
    float   diffuse     = max(dot(lightDirection, fNormal), 0.0);

    if (diffuse == 0.0)
    {
        specular = 0.0;
    }
    else
    {
        specular = pow(specular, specularShininess) * specularIntensity;
    }

    color = texColor * diffuse * lightColor + min(specular * lightColor, vec4(1.0));
}

我对如何计算halfVector有点困惑。我正在CPU上进行处理，并将其作为制服传递给它。计算方法如下:

vec3    lightDirection(1.0, 1.0, 1.0);
lightDirection = normalize(lightDirection);
vec3    eyeDirection(0.0, 0.0, 1.0);
eyeDirection = normalize(eyeDirection);
vec3    halfVector  = lightDirection + eyeDirection;
halfVector = normalize(halfVector);
glUniform3fv(halfVectorLoc, 1, &halfVector [ 0 ]);

那是halfVector的正确公式吗？还是也需要在着色器中完成？

最佳答案

将法线插入脸部可以(几乎总是)将法线缩短。因此，高光在脸部中央变暗，而在角落和边缘变亮。如果执行此操作，只需在片段着色器中重新规范法线即可:

fNormal = normalize(fNormal);

顺便说一句，您不能预先计算半个向量，因为它取决于视图(这是镜面照明的整个要点)。在当前情况下，仅移动摄像机(保持方向)，高光将不会改变。

在着色器中执行此操作的一种方法是为眼睛位置传递附加的制服，然后将视图方向计算为eyePosition - vertexPosition。然后像在CPU上一样继续操作。