camera - 有没有一种方法可以将Alpha蒙版应用于FlxCamera？

我正在尝试实现this camera，但是我现在面临的障碍之一是两个摄像头（他所描述的here）的合并。

最初，我尝试制作非矩形相机，但我认为不改变HaxeFlixel渲染方式的很多事情是不可能的。

然后我在alphaMask()包中找到了FlxSpriteUtil函数，我认为这将是一个更好的解决方案。
它不仅可以解决我的问题，而且实际上允许使用各种时髦的照相机，您只需要创建正确的遮罩即可！

但是新的问题是，我不知道如何将其应用于相机（如果可能，又不作任何改动，再次FlxCamera）。

在内部，FlxCamera可能使用FlxSprite，但仅在blit渲染模式下使用，而我在图块渲染模式下（尚未找到如何进行更改，我认为这种解决方案不够好），该模式使用Flash Sprite相反，我不知道该怎么办。

简而言之，您是否知道如何将AlphaMask应用于FlxCamera？还是实现我想要做的另一种方式？

PS：如果您想看看（丑陋且带有法语注释的）代码，它已经超过了here！

最佳答案

您可以将FlxCamera的内容渲染为FlxSprite（尽管它确实需要基于渲染模式的条件代码）。 TurnBasedRPG tutorial game在战斗屏幕中将其用于波浪效果，请参见CombatHUD.hx：

if (FlxG.renderBlit)
    screenPixels.copyPixels(FlxG.camera.buffer, FlxG.camera.buffer.rect, new Point());
else
    screenPixels.draw(FlxG.camera.canvas, new Matrix(1, 0, 0, 1, 0, 0));

这是一个使用此代码创建HaxeFlixel形相机的代码示例：

package;

import flixel.tweens.FlxTween;
import flash.geom.Matrix;
import flixel.FlxCamera;
import flixel.FlxG;
import flixel.FlxSprite;
import flixel.FlxState;
import flixel.graphics.FlxGraphic;
import flixel.system.FlxAssets;
import flixel.util.FlxColor;
import openfl.geom.Point;
using flixel.util.FlxSpriteUtil;

class PlayState extends FlxState
{
    static inline var CAMERA_SIZE = 100;

    var maskedCamera:FlxCamera;
    var cameraSprite:FlxSprite;
    var mask:FlxSprite;

    override public function create():Void
    {
        super.create();

        maskedCamera = new FlxCamera(0, 0, CAMERA_SIZE, CAMERA_SIZE);
        maskedCamera.bgColor = FlxColor.WHITE;
        maskedCamera.scroll.x = 50;
        FlxG.cameras.add(maskedCamera);

        // this is a bit of a hack - we need this camera to be rendered so we can copy the content
        // onto the sprite, but we don't want to actually *see* it, so just move it off-screen
        maskedCamera.x = FlxG.width;

        cameraSprite = new FlxSprite();
        cameraSprite.makeGraphic(CAMERA_SIZE, CAMERA_SIZE, FlxColor.WHITE, true);
        cameraSprite.x = 50;
        cameraSprite.y = 100;
        cameraSprite.cameras = [FlxG.camera];
        add(cameraSprite);

        mask = new FlxSprite(FlxGraphic.fromClass(GraphicLogo));

        var redSquare = new FlxSprite(0, 25);
        redSquare.makeGraphic(50, 50, FlxColor.RED);
        add(redSquare);
        FlxTween.tween(redSquare, {x: 150}, 1, {type: FlxTween.PINGPONG});
    }

    override public function update(elapsed:Float):Void
    {
        super.update(elapsed);

        var pixels = cameraSprite.pixels;
        if (FlxG.renderBlit)
            pixels.copyPixels(maskedCamera.buffer, maskedCamera.buffer.rect, new Point());
        else
            pixels.draw(maskedCamera.canvas);

        cameraSprite.alphaMaskFlxSprite(mask, cameraSprite);
    }
}