haskell - Haskell中具有多态性的参照透明

说我有一个功能:

f :: Int -> (Rational, Integer)
f b = ((toRational b)+1,(toInteger b)+1)

我想像这样抽象(+1):

f :: Int -> (Rational, Integer)
f b = (h (toRational b)
      ,h (toInteger b))
    where h = (+1)

这显然不会起作用，但是如果我指定类型签名，它将起作用:

f :: Int -> (Rational, Integer)
f b = (h (toRational b)
      ,h (toInteger b))
    where h :: Num a => a -> a
          h = (+1)

假设我现在想通过将h作为参数来进一步抽象该函数:

f :: Num a => Int -> (a -> a) -> (Rational, Integer)
f b g = (h (toRational b)
        ,h (toInteger b))
    where h :: Num a => a -> a
          h = g

我收到一个错误，即内部a与外部a不相同。

有人知道如何正确编写此函数吗？
我想将一个多态函数g传递给f并多态使用它。

我现在在非常不同的项目中多次遇到这种情况，而我找不到一个好的解决方案。

最佳答案

我找到了解决方案:像这样使用forall量词:

{-# LANGUAGE RankNTypes #-}
f :: Int -> (forall a. Num a=> a -> a) -> (Rational, Integer)
f b g = (h (toRational b)
        ,h (toInteger b))
    where h :: Num a => a -> a
          h = g

当然可以将其转换为:

f :: Int -> (forall a. Num a=>a -> a) -> (Rational, Integer)
f b g = (g (toRational b)
        ,g (toInteger b))