excel - VBA-从电子表格的内容创建ADODB.Recordset

我正在查询SQL数据库的Excel应用程序。查询可能需要很长时间才能运行(20-40分钟)。如果我对某些内容进行了错误编码，则可能需要很长时间才能出错或到达断点。我可以将结果保存到一张纸上，因为当我使用记录集时，事情可能会崩溃。

当我调试跳过查询数据库(第一次之后)时，是否可以将数据加载到ADODB.Recordset中？

我会用这样的东西吗？

Query Excel worksheet in MS-Access VBA (using ADODB recordset)

最佳答案

我必须安装MDAC才能获取msado15.dll，一旦安装了它，便添加了对它的引用(在Win7 64bit上):

C:\Program Files(x86)\Common Files\System\ado\msado15.dll

然后，我通过传入当前事件工作簿中存在的工作表名称，创建了一个返回ADODB.Recordset对象的函数。这是其他任何需要的代码，包括一个Test()子程序，以查看其是否有效:

Public Function RecordSetFromSheet(sheetName As String)

Dim rst As New ADODB.Recordset
Dim cnx As New ADODB.Connection
Dim cmd As New ADODB.Command

    'setup the connection
    '[HDR=Yes] means the Field names are in the first row
    With cnx
        .Provider = "Microsoft.Jet.OLEDB.4.0"
        .ConnectionString = "Data Source='" & ThisWorkbook.FullName & "'; " & "Extended Properties='Excel 8.0;HDR=Yes;IMEX=1'"
        .Open
    End With

    'setup the command
    Set cmd.ActiveConnection = cnx
    cmd.CommandType = adCmdText
    cmd.CommandText = "SELECT * FROM [" & sheetName & "$]"
    rst.CursorLocation = adUseClient
    rst.CursorType = adOpenDynamic
    rst.LockType = adLockOptimistic

    'open the connection
    rst.Open cmd

    'disconnect the recordset
    Set rst.ActiveConnection = Nothing

    'cleanup
    If CBool(cmd.State And adStateOpen) = True Then
        Set cmd = Nothing
    End If

    If CBool(cnx.State And adStateOpen) = True Then cnx.Close
    Set cnx = Nothing

    '"return" the recordset object
    Set RecordSetFromSheet = rst

End Function

Public Sub Test()

Dim rstData As ADODB.Recordset
Set rstData = RecordSetFromSheet("Sheet1")

Sheets("Sheet2").Range("A1").CopyFromRecordset rstData

End Sub

Sheet1数据:
场1场2场3
红A 1
蓝色B 2
绿色C 3

应该复制到Sheet2的内容:
红A 1
蓝色B 2
绿色C 3

每次我想进行更改并进行测试时，这节省了我大量的时间来查询SQL ...

-罗伯特

关于excel - VBA-从电子表格的内容创建ADODB.Recordset，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/2484516/