excel - 在“Dependents.Count”中使用“Worksheet_SelectionChange”语句时重新启动宏

我试图获取所选范围的依赖项数量(如果所选单元格的数量为一)。当我使用以下代码时，它对所有单元格都适用，没有任何错误(对于没有任何依赖关系的单元格以及具有依赖关系的单元格)

'Case 1
Sub Example()
    Dim rng As Excel.Range
    Set rng = Excel.Selection
    If Target.Count = 1 Then
        If HasDependents(rng) Then
            MsgBox rng.Dependents.Count & " dependancies found."
        Else
            MsgBox "No dependancies found."
        End If
    End If
End Sub

Public Function HasDependents(ByVal Something As Excel.Range) As Boolean
    On Error Resume Next
    HasDependents = Something.Dependents.Count
End Function

但是，当在Worksheet_SelectionChange中使用相同的逻辑时(如以下代码所示)

'Case 2
Sub Worksheet_SelectionChange(ByVal Target As Excel.Range)
    If Target.Count = 1 Then
        If HasDependents(Target) Then
            MsgBox Target.Dependents.Count & " dependancies found."
        Else
            MsgBox "No dependancies found."
        End If
    End If
End Sub

Public Function HasDependents(ByVal Something As Excel.Range) As Boolean
    On Error Resume Next
    HasDependents = Something.Dependents.Count
End Function

它适用于不具有任何依存关系的单元格，但适用于具有依存关系的单元格“Dependents.Count”重新启动宏。执行后

HasDependents = Something.Dependents.Count

语句，宏重新启动并执行

Sub Worksheet_SelectionChange(ByVal Target As Excel.Range)

再次。我的问题是，为什么宏在执行“Dependents.Count”后在第二种情况下重新启动？ 对于“Worksheet_SelectionChange”，我已将代码放在“工作表代码”区域而不是模块中。

最佳答案

询问Dependents property似乎正在触发单元选择事件。此外，每当未找到依赖项时，就会出现错误1004:未找到任何单元格。 被抛出。对依赖项的检索似乎是递归的；进入每个被发现为依赖的人，以找到另一层依赖。

我通过添加禁用Application.EnableEvents property的调用来稳定您的过程，以使例程不会被自身调用。

Sub Worksheet_SelectionChange(ByVal Target As Excel.Range)
    If Target.Count = 1 Then
        On Error GoTo bm_Err_Exit
        Dim dc As Long
        Application.EnableEvents = False
        dc = Target.Dependents.Count
        If CBool(dc) Then
            'MsgBox Target.Address(0, 0) & Chr(10) & Chr(10) & _
                    dc & " dependancies found."
            Debug.Print Target.Address(0, 0) & Chr(10) & _
                    dc & " dependancies found."
        Else
            'never reaches here; error 1004 is thrown when no dependents
            'MsgBox "No dependancies found."
            Debug.Print "No dependancies found."
        End If
    End If
bm_Safe_Exit:
    Application.EnableEvents = True
    Exit Sub
bm_Err_Exit:
    Debug.Print Err.Number & ": " & Err.Description
    Application.EnableEvents = True
End Sub

当前选择没有任何依赖项时，基本错误控制报告1004错误。

¹您可能想探索DirectDependents property和Dependents property。