delphi - 从一种形式拖放到另一种形式的任何位置

我有一个带有两个表单的MDI表单应用程序。第一个具有StringGrid，第二个表单具有许多Edit控件和一些按钮。

我需要从网格中拖放到第二个Form上，并用第一个Form中StringGrid中所选单元格的值更新一个Edit。

如果我事先知道用户将释放鼠标左键，这是很容易做到的，因为我可以设置该特定控件的OnDragDrop事件。但是我不想为第二个窗体上的每个控件编写多个OnDragDrop事件。

如何拦截整个窗体的消息以拦截ANY控件上的放置操作？

最佳答案

在StringGrid的DragObject事件中设置自定义OnStartDrag：

{ TMyDragObject }

type
  TMyDragObject = class(TDragControlObjectEx)
  protected
    DragText: String;
    procedure Finished(Target: TObject; X, Y: Integer; Accepted: Boolean); override;
    function GetDragCursor(Accepted: Boolean; X, Y: Integer): TCursor; override;
  end;

procedure TMyDragObject.Finished(Target: TObject; X, Y: Integer; Accepted: Boolean);
begin
  if Target is TCustomEdit then
    TCustomEdit(Target).SelText := DragText;
  inherited;
end;

function TMyDragObject.GetDragCursor(Accepted: Boolean; X, Y: Integer): TCursor;
begin
  if TObject(DragTarget) is TCustomEdit then
    Result := crDrag
  else
    Result := inherited GetDragCursor(Accepted, X, Y);
end;

{ TForm1 }

procedure TForm1.StringGrid1StartDrag(Sender: TObject; var DragObject: TDragObject);
begin
  DragObject := TMyDragObject.Create(StringGrid1);
  TMyDragObject(DragObject).DragText := StringGrid1.Cells[StringGrid1.Col,
    StringGrid1.Row];
end;