如果使用Subversion在整个团队中同步工作并将Harvest作为企业记录系统，您将如何集成Subversion和CA Harvest SCM？
我正在研究的一种方法是创建一个将SVN标签加载到Harvest中的脚本，但是很好奇是否有人在此之前做了类似的事情，或者是否有更好的方法来解决该问题。
最佳答案
我最终创建了一个脚本来同步Subversion和Harvest。我们不必同步另一种方式，但是更改脚本来做到这一点并不困难。您可以在此处 check out 脚本-> http://developerdad.com/2011/03/28/synchronize-subversion-to-ca-allfusion-harvest/
我们现在在我们的Jenkins(以前称为Hudson)CI服务器上使用此脚本，因此每次运行Production生成时，都会创建一个新的Harvest包(由Jenkins设置的％JOB_NAME％变量命名)。
更新
该网站已经上下，所以下面是脚本:
@echo off
REM ###########################################################################
REM #
REM # Script file to move changes from Subversion to Harvest
REM #
REM ###########################################################################
if "%1" == "" goto usage
setlocal
set PROJECT_STAGE=-b "" -en "" -st ""
set VIEW=-vp ""
set CREDENTIALS=-usr "" -pw ""
set SUBVERSION_REPO=svn:////trunk/
REM Clean up any build artifacts if present
call ant clean
REM Create Harvest package
hcp %1 %PROJECT_STAGE% %CREDENTIALS%
REM Delete the checked-out Subversion code
REM Note: You will need to remove everything (except this file of course), so more rmdir or del statements may be required below
rmdir /S /Q project
REM Check out the files in Harvest to modify
hco * %PROJECT_STAGE% %CREDENTIALS% %VIEW% -p "%1" -pn "Check Out Files for Update" -up -r -s * -op pc -cp %CD%
REM Delete the checked-out Harvest code
REM Note: You will need to remove everything (except this file of course), so more rmdir or del statements may be required below
rmdir /S /Q project
REM Replace with the latest code from Subversion repository
svn co %SUBVERSION_REPO% .
REM Delete the .svn directories
for /f "tokens=* delims=" %%i in ('dir /s /b /a:d *svn') do (
rd /s /q "%%i"
)
REM What are the updates for Harvest? Check them into Harvest
hci * %PROJECT_STAGE% %CREDENTIALS% %VIEW% -p "%1" -pn "Check In Modified Files" -s * -ur -de "Added in Subversion" -if ne -op pc -cp %CD%
REM Remove the log files from Harvest
REM Note: You may need to change or remove this statement depending on whether you want the Harvest logs checked in
hdv *.log %PROJECT_STAGE% %CREDENTIALS% %VIEW% -pn "Delete Versions"
REM What removals from Harvest do we need to process? (What files were deleted in Subversion?)
hsv %PROJECT_STAGE% %CREDENTIALS% %VIEW% -p "%1" -it r -s "*"
REM This will not work if the file path has spaces in it. You can use %%j %%k ... in the -vp switch for one space in your project name (For example, if you have 2 spaces, it should be -vp %%j %%k %%l)
for /f "tokens=1-5 skip=3" %%i in (hsv.log) do (
if not "%%i"=="hsv" (
hci "%%i" %PROJECT_STAGE% %CREDENTIALS% -vp "%%j" -p "%1" -pn "Check In Modified Files" -ro -cp %CD%
hri "%%i" %PROJECT_STAGE% %CREDENTIALS% -vp "%%j" -p "%1"
)
)
REM remove read-only attribute from all files
attrib -r -h * /s
REM delete all harvest.sig files
del /f /s /q harvest.sig
endlocal
goto end
:usage
echo USAGE:
echo -----------------------------------------------------------------------------
echo "svn2harvest {package_name}"
echo -----------------------------------------------------------------------------
:end
关于svn - 同步Subversion和Harvest SCM存储库？，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/965379/