linux - Yocto Bitbake食谱如何覆盖do_install()和do_install_append()

我正在尝试将开放源代码“procps”软件包添加到我的工作Yocto构建中。此软件包将安装一堆二进制文件，以替换BusyBox提供的二进制文件。我只想要这些二进制文件之一-pgrep。

在我的图层中，我创建了一个名为“procps_％bbappend”的bbappend文件。它由构建程序拾取，成功编译，但随后安装失败。错误消息似乎表明do_install()和do_install_append()挂钩没有被完全覆盖。

如何更改我的bitbake bbappend文件，使其仅安装pgrep实用程序，而从“procps”软件包中没有其他标准安装？

这是我的bbappend文件失败:

do_install () {
    install -d ${D}${base_bindir}
    mv ${D}/../build/pgrep ${D}/bin/pgrep
}

do_install_append () {
    install -d ${D}${base_bindir}
    mv ${D}/../build/pgrep ${D}/bin/pgrep
}

bindir_progs = ""
base_bindir_progs = ""
base_sbindir_progs = ""

这是整个“procps”位烘烤食谱:

SUMMARY = "System and process monitoring utilities"
DESCRIPTION = "Procps contains a set of system utilities that provide system information about processes using \
the /proc filesystem. The package includes the programs ps, top, vmstat, w, kill, and skill."
HOMEPAGE = "https://gitorious.org/procps"
SECTION = "base"
LICENSE = "GPLv2+ & LGPLv2+"
LIC_FILES_CHKSUM="file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
                  file://COPYING.LIB;md5=4cf66a4984120007c9881cc871cf49db \
                 "

DEPENDS = "ncurses"

inherit autotools gettext pkgconfig update-alternatives

SRC_URI = "http://downloads.sourceforge.net/project/procps-ng/Production/procps-ng-${PV}.tar.xz \
           file://sysctl.conf \
          "

SRC_URI[md5sum] = "6cc5b94c1c5b8cbc89ad345a7b522f74"
SRC_URI[sha256sum] = "e9493169a2d2adc0bc045538707310c8e877b385e4e296143b62607d2bb044ed"

S = "${WORKDIR}/procps-ng-${PV}"

EXTRA_OECONF = "--enable-skill --disable-modern-top"

CPPFLAGS += "-I${S}"

do_install_append () {
    install -d ${D}${base_bindir}
    [ "${bindir}" != "${base_bindir}" ] && for i in ${base_bindir_progs}; do mv ${D}${bindir}/$i ${D}${base_bindir}/$i; done
    install -d ${D}${base_sbindir}
    [ "${sbindir}" != "${base_sbindir}" ] && for i in ${base_sbindir_progs}; do mv ${D}${sbindir}/$i ${D}${base_sbindir}/$i; done
        if [ "${base_sbindir}" != "${sbindir}" ]; then
                rmdir ${D}${sbindir}
        fi

        install -d ${D}${sysconfdir}
        install -m 0644 ${WORKDIR}/sysctl.conf ${D}${sysconfdir}/sysctl.conf
        if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
                install -d ${D}${sysconfdir}/sysctl.d
                ln -sf ../sysctl.conf ${D}${sysconfdir}/sysctl.d/99-sysctl.conf
        fi
}

CONFFILES_${PN} = "${sysconfdir}/sysctl.conf"

bindir_progs = "free pkill pmap pgrep pwdx skill snice top uptime"
base_bindir_progs += "kill pidof ps watch"
base_sbindir_progs += "sysctl"

ALTERNATIVE_PRIORITY = "200"

ALTERNATIVE_${PN} = "${bindir_progs} ${base_bindir_progs} ${base_sbindir_progs}"

ALTERNATIVE_${PN}-doc = "kill.1 uptime.1"
ALTERNATIVE_LINK_NAME[kill.1] = "${mandir}/man1/kill.1"
ALTERNATIVE_LINK_NAME[uptime.1] = "${mandir}/man1/uptime.1"

python __anonymous() {
    for prog in d.getVar('base_bindir_progs', True).split():
        d.setVarFlag('ALTERNATIVE_LINK_NAME', prog, '%s/%s' % (d.getVar('base_bindir', True), prog))

    for prog in d.getVar('base_sbindir_progs', True).split():
        d.setVarFlag('ALTERNATIVE_LINK_NAME', prog, '%s/%s' % (d.getVar('base_sbindir', True), prog))
}

最佳答案

这里有些困惑:

您不能“替代”另一个_append:原始配方中的一个仍将追加

即使可以，您的版本也会尝试两次将同一文件转换为mv(在安装和追加中):这将失败。通常，在这里使用mv是个坏主意:使用install就是这样做的。

使用${D}/../build/是不正确的，您可能需要${B}，但是它也应该是do_install()的默认目录，因此您根本不需要它。

您可以让原始的do_install()做它想要的事情，然后在do_install_append()中删除不需要的位...但是我认为对包进行太多修改不是一个好主意:如果另一个包运行时取决于在procps上，并期望您删除了工具？

一些替代方案:

用新名称复制配方，然后对其进行修改

让do_install保持原样，然后在bbappend中添加一个新软件包PACKAGES =+ ${PN}-pgrep并设置FILES_${PN}-pgrep = "${bindir}/pgrep":这样，您只能安装新的微小procps-pgrep软件包，而不是procps。由于系统procps使用的替代方法，因此可能需要进行一些调整才能正确使用...