windows - Windows批处理: delayed expansion in a for loop

我想修改几行特定数量的文本文件，并编写了一个批处理文件，如下所示:

@echo off
set n=0
set n1=10
set n2=40
cd.>output.txt

for /f "delims=" %%i in ('findstr /n .* test.txt') do (
set "var=%%i"
setlocal enabledelayedexpansion
set /a n=!n!+1
echo.!n!
set var=!var:*:=!
rem if !n!=%n1% ...
rem if !n!=%n2% ...
(echo.!var!)>>output.txt
endlocal
)
start output.txt

但是，这不符合预期。
经过一些测试，我认为!n!扩展通常不会延迟。这很奇怪，因为!var!扩展通常会延迟。

顺便说一下，将setlocal enabledelayedexpansion和endlocal命令放入for循环中，因为否则将放弃特殊字符!。

最佳答案

我想您看到的问题是n永远不会增加。

但这不是延迟扩展的问题，它是循环内setlocal/endlocal块的作用。
如@ panda-34所述，您应该使用set/a的扩展语法并将该语句移到setlocal/endlocal块之外。

@echo off
set n=0
set n1=10
set n2=40

(
  for /f "delims=" %%i in ('findstr /n .* test.txt') do (
    set "var=%%i"
    set /a n+=1
    setlocal enabledelayedexpansion
    echo !n!
    set var=!var:*:=!
    rem if !n!=%n1% ...
    rem if !n!=%n2% ...
    (echo(!var!)
    endlocal
  )
) >output.txt
start output.txt

关于windows - Windows批处理: delayed expansion in a for loop，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/10960467/