vbscript - CDO.Message-“传输无法连接到服务器。”

我正在使用CDO.Message在功能中发送电子邮件的Classic ASP＆Vbscript网站上工作。我在使用此功能时遇到了麻烦，并且正在收到错误消息，

CDO.Message.1 error '80040213'

The transport failed to connect to the server.

我相信这与SMTP身份验证设置和我们正在运行的共享主机有关。我正在寻找进一步调试问题的帮助。

这是该函数的主要代码段，

Set objConfig = Server.CreateObject("CDO.Configuration")
Set Fields = objConfig.Fields

' Set config fields we care about
With Fields
 .Item(cdoSendUsingMethod)       = cdoSendUsingPort
 .Item(cdoSMTPServer)            = "mail.<website>.com"

 '.Item(cdoSMTPServerPort)        = 25
 '.Item(cdoSMTPConnectionTimeout) = 10
 '.Item(cdoSMTPAuthenticate)      = cdoBasic
 '.Item(cdoSendUserName)          = "support"
 '.Item(cdoSendPassword)          = "password"

 .Update
End With

Set objMessage = Server.CreateObject("CDO.Message")

Set objMessage.Configuration = objConfig

With objMessage
 .To       = lEmailTo                   '"Display Name <email_address>"
 .From     = lEmailFrom                 '"Display Name <email_address>"
 .Subject  = lSubject
 .TextBody = lMessage
 .Send
End With

起初，我认为上面的代码片段中可能包含9-13行，但似乎以前的开发人员故意对此进行了评论，并且电子邮件功能在某个时间点仍在起作用。取消注释这些行仍然不能解决错误。

有人可以看到我可能会丢失的东西吗？有谁知道CDO.Configuration的默认设置是什么以及此代码试图与我们的共享主机一起使用的SMTP设置吗？我应该先打电话给我们的托管服务商并与他们澄清一下吗？

最佳答案

在使用CDO之前，我遇到了一段艰难的时光，直到在asp页面顶部添加了typelib。请注意，typelib不在分隔符内。 typelib行很长，因此您需要向右滚动以阅读所有内容

首先尝试仅将typelib语句添加到您的页面。

如果那不起作用，请尝试下面的其余代码。我已经在Godaddy托管的网站上成功使用了此代码。当然，如果需要，您必须插入邮件服务器信息和登录名/密码。

<!--METADATA TYPE="typelib" UUID="CD000000-8B95-11D1-82DB-00C04FB1625D" NAME="CDO for Windows 2000 Type Library" -->
<%
Sub SendEmail()

    Set cdoConfig = CreateObject("CDO.Configuration")

    if lcase(Request.ServerVariables("SERVER_NAME")) = "dev" then
            With cdoConfig.Fields
                    .Item(cdoSendUsingMethod) = cdoSendUsingPort
                    .Item(cdoSMTPServer) = "xxx.<devmailservername>.xxx"
                    .Item(cdoSMTPAuthenticate) = 1
                    .Item(cdoSendUsername) = "[email protected]"
                    .Item(cdoSendPassword) = "<passwordgoeshere>"
                    .Update
            End With
    else
            With cdoConfig.Fields
                    .Item(cdoSendUsingMethod) = cdoSendUsingPort
                    .Item(cdoSMTPServer) = "xxx.<productionmailservername>.xxx"
                    .Update
            End With
    end if

    Set cdoMessage = CreateObject("CDO.Message")

    With cdoMessage
        Set .Configuration = cdoConfig
        .From = "[email protected]"
        .To = "[email protected]"
        .Subject = "Sample CDO Message"
        .htmlbody = "<html><body>Sample <b>CDO</b> message.</body></html>"
        .TextBody = "Sample CDO Message."
        .Send
    End With

    Set cdoMessage = Nothing
    Set cdoConfig = Nothing

End Sub
%>

TypeLib

vbscript - CDO.Message-“传输无法连接到服务器。”