idris - Idris中的依赖类型的printf

我正在尝试将Cayenne的一个示例翻译为Idris-一种具有依赖类型paper的语言。

这是我到目前为止的内容：

PrintfType : (List Char) -> Type
PrintfType Nil                = String
PrintfType ('%' :: 'd' :: cs) = Int -> PrintfType cs
PrintfType ('%' :: 's' :: cs) = String -> PrintfType cs
PrintfType ('%' ::  _  :: cs) = PrintfType cs
PrintfType ( _  :: cs)        = PrintfType cs

printf : (fmt: List Char) -> PrintfType fmt
printf fmt = rec fmt "" where
  rec : (f: List Char) -> String -> PrintfType f
  rec Nil acc = acc
  rec ('%' :: 'd' :: cs) acc = \i => rec cs (acc ++ (show i))
  rec ('%' :: 's' :: cs) acc = \s => rec cs (acc ++ s)
  rec ('%' ::  _  :: cs) acc = rec cs acc  -- this is line 49
  rec ( c  :: cs)        acc = rec cs (acc ++ (pack [c]))

我使用List Char而不是String作为format参数，以方便进行模式匹配，因为我很快遇到了String上的模式匹配的复杂性。

不幸的是，我收到一条错误消息，我无法理解：

Type checking ./sprintf.idr
sprintf.idr:49:Can't unify PrintfType (Prelude.List.:: '%' (Prelude.List.:: t cs)) with PrintfType cs

Specifically:
    Can't convert PrintfType (Prelude.List.:: '%' (Prelude.List.:: t cs)) with PrintfType cs

如果我注释掉所有在'%' :: ...和PrintfType中具有3个元素（带有printf的元素）的模式匹配用例，则代码会编译（但显然没有做任何有趣的事情）。

如何修复我的代码，以使printf "the %s is %d" "answer" 42有效？

最佳答案

在定义模式重叠的函数（例如'%' :: 'd'与c :: cs重叠）时，idris中似乎有一些current limitations。经过多次尝试，我终于找到了解决方法：

data Format = End | FInt Format | FString Format | FChar Char Format
fromList : List Char -> Format
fromList Nil                = End
fromList ('%' :: 'd' :: cs) = FInt    (fromList cs)
fromList ('%' :: 's' :: cs) = FString (fromList cs)
fromList (c :: cs)          = FChar c (fromList cs)

PrintfType : Format -> Type
PrintfType End            = String
PrintfType (FInt rest)    = Int -> PrintfType rest
PrintfType (FString rest) = String -> PrintfType rest
PrintfType (FChar c rest) = PrintfType rest

printf : (fmt: String) -> PrintfType (fromList $ unpack fmt)
printf fmt = printFormat (fromList $ unpack fmt) where
  printFormat : (fmt: Format) -> PrintfType fmt
  printFormat fmt = rec fmt "" where
    rec : (f: Format) -> String -> PrintfType f
    rec End acc            = acc
    rec (FInt rest) acc    = \i: Int => rec rest (acc ++ (show i))
    rec (FString rest) acc = \s: String => rec rest (acc ++ s)
    rec (FChar c rest) acc = rec rest (acc ++ (pack [c]))

Format是表示格式字符串的递归数据类型。 FInt是一个int占位符，FString是一个字符串占位符，FChar是一个字符常量。使用Format可以定义PrintfType并实现printFormat。从那里，我可以顺利地扩展以采用字符串而不是List Char或Format值。最终结果是：

*sprintf> printf "the %s is %d" "answer" 42
"the answer is 42" : String

关于idris - Idris中的依赖类型的printf，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/17905537/