c++ - 在OpenGL/GLSL中绘制镶嵌 segmentation 的LineLoop

我正在渲染球体上的一些LineLoop(行星上的边界)，并希望将它们细分成更短的线，以防止长线夹入球体。
例:


这是我当前的源代码:
C++绘图调用:

void Border::Draw() const
{
    glBindVertexArray(_vao);

    glPatchParameteri(GL_PATCH_VERTICES, 2);
    glDrawArrays(GL_PATCHES, 0, _size);

    glBindVertexArray(0);
}

顶点着色器:

#version 400

in layout(location = 0) vec3 position;

void main()
{
    gl_Position = vec4(position, 1.0);
}

镶嵌控制着色器:

#version 400

layout (vertices = 2) out;

void main()
{
    if(gl_InvocationID == 0)
    {
        //get the distance between two points
        float dist = length(gl_in[0].gl_Position - gl_in[1].gl_Position);
        gl_TessLevelOuter[0] = 1;
        //divide line in segments of size 1.0
        gl_TessLevelOuter[1] = abs(dist);
    }

    gl_out[gl_InvocationID].gl_Position = gl_in[gl_InvocationID].gl_Position;
}

镶嵌评估着色器

#version 400

layout (isolines, equal_spacing) in;

uniform float planetRadius;
uniform mat4 view;
uniform mat4 projection;

void main()
{
    vec4 p = mix(gl_in[0].gl_Position, gl_in[1].gl_Position, gl_TessCoord.x);

    //offset point so it is on the spheres surface
    p = normalize(p);
    p *= planetRadius;

    gl_Position = projection * view * p;
}

片段着色器:

#version 400

out vec4 outColor;

void main()
{
    outColor = vec4(1.0, 1.0, 1.0, 1.0);
}

镶嵌细分似乎无法像我期望的那样工作(等值线文档也很糟糕)。

这是当我使用LineLoops和仅“顶点/片段着色器”绘制时的外观:



这是我实现镶嵌处理后的样子:



这些线看起来也没有棋盘格形，并且长度与以前相同。

问候乔尼

编辑:
自己找到解决方案。在下面的答案部分中查看它。

最佳答案

我找到了解决方案。问题在于tessallation着色器无法绘制线条。因此，如果您拥有由点{p1, p2, p3, p4, p5, p6}定义的线带，则会在以下位置之间绘制线:
p1-> p2
p3-> p4
p5-> p6

我通过给着色器每个点2次来修复它，因此我的列表如下所示:{p1, p2, p2, p3, p3, p4, p4, p5, p5, p6, p6, p1}镶嵌细分着色器创建以下行:
p1-> p2
p2-> p3
p3-> p4
p4-> p5
p5-> p6
p6-> p1

我的着色器现在看起来像这样:

TessControl:

#version 430

layout (vertices = 2) out;

void main()
{
    if(gl_InvocationID == 0)
    {
        float dist = length(gl_in[0].gl_Position.xyz - gl_in[1].gl_Position.xyz);

        gl_TessLevelOuter[0] = 1;
        gl_TessLevelOuter[1] = dist;
    }

    gl_out[gl_InvocationID].gl_Position = gl_in[gl_InvocationID].gl_Position;
}

TessEval:

#version 430

layout (isolines, equal_spacing) in;

uniform float planetRadius;
uniform mat4 view;
uniform mat4 projection;

void main()
{
    //only interpolate and normalize xyz coordinates. Thanks to @aslg
    vec3 p = mix(gl_in[0].gl_Position.xyz, gl_in[1].gl_Position.xyz, gl_TessCoord.x);

    p = normalize(p);
    p *= planetRadius;

    gl_Position = projection * view * vec4(p, 1.0);
}

关于c++ - 在OpenGL/GLSL中绘制镶嵌 segmentation 的LineLoop，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/36883460/