python - 当文件没有.py扩展名时运行python的flymake

我根本不是一个lisp人，但是我的主要脚本环境是在emacs上，当文件没有.py扩展名时，我需要一些帮助来运行flymake/pyflakes因为我工作中的一些脚本没有.py扩展名。
当我在读取/编写扩展名为.py的文件时，这对于pylint、pep8、pychecker等非常有用。

;; flymake for python
(add-to-list 'load-path "~/.emacs.d/plugins/flymake")

(when (load "flymake" t)
  (defun flymake-pylint-init (&optional trigger-type)
    (let* ((temp-file (flymake-init-create-temp-buffer-copy
                       'flymake-create-temp-with-folder-structure))
           (local-file (file-relative-name
                        temp-file
                        (file-name-directory buffer-file-name)))
           (options (when trigger-type (list "--trigger-type" trigger-type))))
      (list "~/.emacs.d/plugins/flymake/pyflymake.py" (append options (list local-file)))))
  (add-to-list 'flymake-allowed-file-name-masks
               '("\\.py\\'" flymake-pylint-init)))

(add-hook 'find-file-hook 'flymake-find-file-hook)

;; flymake help on minibuffer
(defun my-flymake-show-help ()
  (when (get-char-property (point) 'flymake-overlay)
   (let ((help (get-char-property (point) 'help-echo)))
    (if help (message "%s" help)))))

(add-hook 'post-command-hook 'my-flymake-show-help)

在没有.py扩展名的情况下，我试图获取这个可工作的init片段我用python模式钩子包装了上面的代码，并将\.py\部分更改为类似于\.*。
然而，这不仅仅是为python文件调用flymake pylint init函数它称之为emacs中打开的任何东西。
顺便说一下，我不能在没有扩展名的文件上使用m-x flymake模式，它不能打开那个小模式。
我很想知道怎么让它工作谢谢！

最佳答案

首先让我说，下面的代码通常不是解决Emacs问题的方法我所做的是加载flymake，然后踩踏其中一个核心功能由于flymake的编写方式，我找不到钩住函数或使用建议的方法如果flymake改变了这个函数或者它的调用方式，它将不再工作也就是说，它已经为我工作了很多年：）
这是基本代码：

(require 'flymake)

(defun flymake-get-file-name-mode-and-masks (file-name)
  "Return the corresponding entry from `flymake-allowed-file-name-masks'."
  (unless (stringp file-name)
    (error "Invalid file-name"))
  (let ((fnm flymake-allowed-file-name-masks)
        (mode-and-masks nil)
        (matcher nil))
    (while (and (not mode-and-masks) fnm)
      (setq matcher (car (car fnm)))
      (if (or (and (stringp matcher) (string-match matcher file-name))
              (and (symbolp matcher) (equal matcher major-mode)))
          (setq mode-and-masks (cdr (car fnm))))
      (setq fnm (cdr fnm)))
    (flymake-log 3 "file %s, init=%s" file-name (car mode-and-masks))
    mode-and-masks))

然后从上面的代码，而不是这个：

(add-to-list 'flymake-allowed-file-name-masks '("\\.py\\'" flymake-pylint-init))

执行以下操作：

(add-to-list 'flymake-allowed-file-name-masks '(python-mode flymake-pylint-init))

您可以对Perl等执行同样的操作。