html - 带有Turbolink的Facebook Twitter按钮

我正在尝试实现两个共享按钮。Facebook Like Button和Twitter Share Button。
但我对涡轮连杆有问题。。我查了一下后发现了一个interesting article。
该解决方案指出，通过从application.html.erb中删除初始脚本并包含以下文件将解决该问题。

fb_root = null
fb_events_bound = false

$ ->
  loadFacebookSDK()
  bindFacebookEvents() unless fb_events_bound

bindFacebookEvents = ->
  $(document)
    .on('page:fetch', saveFacebookRoot)
    .on('page:change', restoreFacebookRoot)
    .on('page:load', ->
      FB?.XFBML.parse()
    )
  fb_events_bound = true

saveFacebookRoot = ->
  fb_root = $('#fb-root').detach()

restoreFacebookRoot = ->
  if $('#fb-root').length > 0
    $('#fb-root').replaceWith fb_root
  else
    $('body').append fb_root

loadFacebookSDK = ->
  window.fbAsyncInit = initializeFacebookSDK
  $.getScript("//connect.facebook.net/en_US/all.js#xfbml=1")

initializeFacebookSDK = ->
  FB.init
    appId     : 'YOUR_APP_ID'
    channelUrl: '//WWW.YOUR_DOMAIN.COM/channel.html'
    status    : true
    cookie    : true
    xfbml     : true

对于Twitter Problem，也是如此：

twttr_events_bound = false

$ ->
  bindTwitterEventHandlers() unless twttr_events_bound

bindTwitterEventHandlers = ->
  $(document).on 'page:load', renderTweetButtons
  twttr_events_bound = true

renderTweetButtons = ->
  $('.twitter-share-button').each ->
    button = $(this)
    button.attr('data-url', document.location.href) unless button.data('url')?
    button.attr('data-text', document.title) unless button.data('text')?
  twttr.widgets.load()

我做到了，但不知为什么我的问题不会消失。。有人能帮我把这个弄对吗？

最佳答案

请参考此问题（投票最多的答案），因此请尝试：

ready = ->

  ...your coffeescript goes here...

$(document).ready(ready)
$(document).on('page:load', ready)

我以前遇到过turbolink的问题，当我在主页中加载fb脚本，然后按照链接转到另一个页面时，fb脚本不会重新加载。所以我试着加上data-turbolink-track = false就成功了。
希望能帮上忙。